d9/d87/slsode_8f_source.html

       SUBROUTINE slsode (F, NEQ, Y, T, TOUT, ITOL, RTOL, ATOL, ITASK,

      1                  ISTATE, IOPT, RWORK, LRW, IWORK, LIW, JAC, MF)

       EXTERNAL f, jac

       INTEGER NEQ, ITOL, ITASK, ISTATE, IOPT, LRW, IWORK, LIW, MF

       REAL Y, T, TOUT, RTOL, ATOL, RWORK

       dimension neq(*), y(*), rtol(*), atol(*), rwork(lrw), iwork(liw)

 C***BEGIN PROLOGUE  SLSODE

 C***PURPOSE  Livermore Solver for Ordinary Differential Equations.

 C            SLSODE solves the initial-value problem for stiff or

 C            nonstiff systems of first-order ODE's,

 C               dy/dt = f(t,y),   or, in component form,

 C               dy(i)/dt = f(i) = f(i,t,y(1),y(2),...,y(N)),  i=1,...,N.

 C***CATEGORY  I1A

 C***TYPE      SINGLE PRECISION (SLSODE-S, DLSODE-D)

 C***KEYWORDS  ORDINARY DIFFERENTIAL EQUATIONS, INITIAL VALUE PROBLEM,

 C             STIFF, NONSTIFF

 C***AUTHOR  Hindmarsh, Alan C., (LLNL)

 C             Center for Applied Scientific Computing, L-561

 C             Lawrence Livermore National Laboratory

 C             Livermore, CA 94551.

 C***DESCRIPTION

 C

 C     NOTE: The "Usage" and "Arguments" sections treat only a subset of

 C           available options, in condensed fashion.  The options

 C           covered and the information supplied will support most

 C           standard uses of SLSODE.

 C

 C           For more sophisticated uses, full details on all options are

 C           given in the concluding section, headed "Long Description."

 C           A synopsis of the SLSODE Long Description is provided at the

 C           beginning of that section; general topics covered are:

 C           - Elements of the call sequence; optional input and output

 C           - Optional supplemental routines in the SLSODE package

 C           - internal COMMON block

 C

 C *Usage:

 C     Communication between the user and the SLSODE package, for normal

 C     situations, is summarized here.  This summary describes a subset

 C     of the available options.  See "Long Description" for complete

 C     details, including optional communication, nonstandard options,

 C     and instructions for special situations.

 C

 C     A sample program is given in the "Examples" section.

 C

 C     Refer to the argument descriptions for the definitions of the

 C     quantities that appear in the following sample declarations.

 C

 C     For MF = 10,

 C        PARAMETER  (LRW = 20 + 16*NEQ,           LIW = 20)

 C     For MF = 21 or 22,

 C        PARAMETER  (LRW = 22 +  9*NEQ + NEQ**2,  LIW = 20 + NEQ)

 C     For MF = 24 or 25,

 C        PARAMETER  (LRW = 22 + 10*NEQ + (2*ML+MU)*NEQ,

 C       *                                         LIW = 20 + NEQ)

 C

 C        EXTERNAL F, JAC

 C        INTEGER  NEQ, ITOL, ITASK, ISTATE, IOPT, LRW, IWORK(LIW),

 C       *         LIW, MF

 C        REAL Y(NEQ), T, TOUT, RTOL, ATOL(ntol), RWORK(LRW)

 C

 C        CALL SLSODE (F, NEQ, Y, T, TOUT, ITOL, RTOL, ATOL, ITASK,

 C       *            ISTATE, IOPT, RWORK, LRW, IWORK, LIW, JAC, MF)

 C

 C *Arguments:

 C     F     :EXT    Name of subroutine for right-hand-side vector f.

 C                   This name must be declared EXTERNAL in calling

 C                   program.  The form of F must be:

 C

 C                   SUBROUTINE  F (NEQ, T, Y, YDOT)

 C                   INTEGER  NEQ

 C                   REAL T, Y(*), YDOT(*)

 C

 C                   The inputs are NEQ, T, Y.  F is to set

 C

 C                   YDOT(i) = f(i,T,Y(1),Y(2),...,Y(NEQ)),

 C                                                     i = 1, ..., NEQ .

 C

 C     NEQ   :IN     Number of first-order ODE's.

 C

 C     Y     :INOUT  Array of values of the y(t) vector, of length NEQ.

 C                   Input:  For the first call, Y should contain the

 C                           values of y(t) at t = T. (Y is an input

 C                           variable only if ISTATE = 1.)

 C                   Output: On return, Y will contain the values at the

 C                           new t-value.

 C

 C     T     :INOUT  Value of the independent variable.  On return it

 C                   will be the current value of t (normally TOUT).

 C

 C     TOUT  :IN     Next point where output is desired (.NE. T).

 C

 C     ITOL  :IN     1 or 2 according as ATOL (below) is a scalar or

 C                   an array.

 C

 C     RTOL  :IN     Relative tolerance parameter (scalar).

 C

 C     ATOL  :IN     Absolute tolerance parameter (scalar or array).

 C                   If ITOL = 1, ATOL need not be dimensioned.

 C                   If ITOL = 2, ATOL must be dimensioned at least NEQ.

 C

 C                   The estimated local error in Y(i) will be controlled

 C                   so as to be roughly less (in magnitude) than

 C

 C                   EWT(i) = RTOL*ABS(Y(i)) + ATOL     if ITOL = 1, or

 C                   EWT(i) = RTOL*ABS(Y(i)) + ATOL(i)  if ITOL = 2.

 C

 C                   Thus the local error test passes if, in each

 C                   component, either the absolute error is less than

 C                   ATOL (or ATOL(i)), or the relative error is less

 C                   than RTOL.

 C

 C                   Use RTOL = 0.0 for pure absolute error control, and

 C                   use ATOL = 0.0 (or ATOL(i) = 0.0) for pure relative

 C                   error control.  Caution:  Actual (global) errors may

 C                   exceed these local tolerances, so choose them

 C                   conservatively.

 C

 C     ITASK :IN     Flag indicating the task SLSODE is to perform.

 C                   Use ITASK = 1 for normal computation of output

 C                   values of y at t = TOUT.

 C

 C     ISTATE:INOUT  Index used for input and output to specify the state

 C                   of the calculation.

 C                   Input:

 C                    1   This is the first call for a problem.

 C                    2   This is a subsequent call.

 C                   Output:

 C                    1   Nothing was done, as TOUT was equal to T.

 C                    2   SLSODE was successful (otherwise, negative).

 C                        Note that ISTATE need not be modified after a

 C                        successful return.

 C                   -1   Excess work done on this call (perhaps wrong

 C                        MF).

 C                   -2   Excess accuracy requested (tolerances too

 C                        small).

 C                   -3   Illegal input detected (see printed message).

 C                   -4   Repeated error test failures (check all

 C                        inputs).

 C                   -5   Repeated convergence failures (perhaps bad

 C                        Jacobian supplied or wrong choice of MF or

 C                        tolerances).

 C                   -6   Error weight became zero during problem

 C                        (solution component i vanished, and ATOL or

 C                        ATOL(i) = 0.).

 C

 C     IOPT  :IN     Flag indicating whether optional inputs are used:

 C                   0   No.

 C                   1   Yes.  (See "Optional inputs" under "Long

 C                       Description," Part 1.)

 C

 C     RWORK :WORK   Real work array of length at least:

 C                   20 + 16*NEQ                    for MF = 10,

 C                   22 +  9*NEQ + NEQ**2           for MF = 21 or 22,

 C                   22 + 10*NEQ + (2*ML + MU)*NEQ  for MF = 24 or 25.

 C

 C     LRW   :IN     Declared length of RWORK (in user's DIMENSION

 C                   statement).

 C

 C     IWORK :WORK   Integer work array of length at least:

 C                   20        for MF = 10,

 C                   20 + NEQ  for MF = 21, 22, 24, or 25.

 C

 C                   If MF = 24 or 25, input in IWORK(1),IWORK(2) the

 C                   lower and upper Jacobian half-bandwidths ML,MU.

 C

 C                   On return, IWORK contains information that may be

 C                   of interest to the user:

 C

 C            Name   Location   Meaning

 C            -----  ---------  -----------------------------------------

 C            NST    IWORK(11)  Number of steps taken for the problem so

 C                              far.

 C            NFE    IWORK(12)  Number of f evaluations for the problem

 C                              so far.

 C            NJE    IWORK(13)  Number of Jacobian evaluations (and of

 C                              matrix LU decompositions) for the problem

 C                              so far.

 C            NQU    IWORK(14)  Method order last used (successfully).

 C            LENRW  IWORK(17)  Length of RWORK actually required.  This

 C                              is defined on normal returns and on an

 C                              illegal input return for insufficient

 C                              storage.

 C            LENIW  IWORK(18)  Length of IWORK actually required.  This

 C                              is defined on normal returns and on an

 C                              illegal input return for insufficient

 C                              storage.

 C

 C     LIW   :IN     Declared length of IWORK (in user's DIMENSION

 C                   statement).

 C

 C     JAC   :EXT    Name of subroutine for Jacobian matrix (MF =

 C                   21 or 24).  If used, this name must be declared

 C                   EXTERNAL in calling program.  If not used, pass a

 C                   dummy name.  The form of JAC must be:

 C

 C                   SUBROUTINE JAC (NEQ, T, Y, ML, MU, PD, NROWPD)

 C                   INTEGER NEQ, ML, MU, NROWPD

 C                   REAL T, Y(*), PD(NROWPD,*)

 C

 C                   See item c, under "Description" below for more

 C                   information about JAC.

 C

 C     MF    :IN     Method flag.  Standard values are:

 C                   10  Nonstiff (Adams) method, no Jacobian used.

 C                   21  Stiff (BDF) method, user-supplied full Jacobian.

 C                   22  Stiff method, internally generated full

 C                       Jacobian.

 C                   24  Stiff method, user-supplied banded Jacobian.

 C                   25  Stiff method, internally generated banded

 C                       Jacobian.

 C

 C *Description:

 C     SLSODE solves the initial value problem for stiff or nonstiff

 C     systems of first-order ODE's,

 C

 C        dy/dt = f(t,y) ,

 C

 C     or, in component form,

 C

 C        dy(i)/dt = f(i) = f(i,t,y(1),y(2),...,y(NEQ))

 C                                                  (i = 1, ..., NEQ) .

 C

 C     SLSODE is a package based on the GEAR and GEARB packages, and on

 C     the October 23, 1978, version of the tentative ODEPACK user

 C     interface standard, with minor modifications.

 C

 C     The steps in solving such a problem are as follows.

 C

 C     a. First write a subroutine of the form

 C

 C           SUBROUTINE  F (NEQ, T, Y, YDOT)

 C           INTEGER  NEQ

 C           REAL T, Y(*), YDOT(*)

 C

 C        which supplies the vector function f by loading YDOT(i) with

 C        f(i).

 C

 C     b. Next determine (or guess) whether or not the problem is stiff.

 C        Stiffness occurs when the Jacobian matrix df/dy has an

 C        eigenvalue whose real part is negative and large in magnitude

 C        compared to the reciprocal of the t span of interest.  If the

 C        problem is nonstiff, use method flag MF = 10.  If it is stiff,

 C        there are four standard choices for MF, and SLSODE requires the

 C        Jacobian matrix in some form.  This matrix is regarded either

 C        as full (MF = 21 or 22), or banded (MF = 24 or 25).  In the

 C        banded case, SLSODE requires two half-bandwidth parameters ML

 C        and MU. These are, respectively, the widths of the lower and

 C        upper parts of the band, excluding the main diagonal.  Thus the

 C        band consists of the locations (i,j) with

 C

 C           i - ML <= j <= i + MU ,

 C

 C        and the full bandwidth is ML + MU + 1 .

 C

 C     c. If the problem is stiff, you are encouraged to supply the

 C        Jacobian directly (MF = 21 or 24), but if this is not feasible,

 C        SLSODE will compute it internally by difference quotients (MF =

 C        22 or 25).  If you are supplying the Jacobian, write a

 C        subroutine of the form

 C

 C           SUBROUTINE  JAC (NEQ, T, Y, ML, MU, PD, NROWPD)

 C           INTEGER  NEQ, ML, MU, NRWOPD

 C           REAL T, Y(*), PD(NROWPD,*)

 C

 C        which provides df/dy by loading PD as follows:

 C        - For a full Jacobian (MF = 21), load PD(i,j) with df(i)/dy(j),

 C          the partial derivative of f(i) with respect to y(j).  (Ignore

 C          the ML and MU arguments in this case.)

 C        - For a banded Jacobian (MF = 24), load PD(i-j+MU+1,j) with

 C          df(i)/dy(j); i.e., load the diagonal lines of df/dy into the

 C          rows of PD from the top down.

 C        - In either case, only nonzero elements need be loaded.

 C

 C     d. Write a main program that calls subroutine SLSODE once for each

 C        point at which answers are desired.  This should also provide

 C        for possible use of logical unit 6 for output of error messages

 C        by SLSODE.

 C

 C        Before the first call to SLSODE, set ISTATE = 1, set Y and T to

 C        the initial values, and set TOUT to the first output point.  To

 C        continue the integration after a successful return, simply

 C        reset TOUT and call SLSODE again.  No other parameters need be

 C        reset.

 C

 C *Examples:

 C     The following is a simple example problem, with the coding needed

 C     for its solution by SLSODE. The problem is from chemical kinetics,

 C     and consists of the following three rate equations:

 C

 C        dy1/dt = -.04*y1 + 1.E4*y2*y3

 C        dy2/dt = .04*y1 - 1.E4*y2*y3 - 3.E7*y2**2

 C        dy3/dt = 3.E7*y2**2

 C

 C     on the interval from t = 0.0 to t = 4.E10, with initial conditions

 C     y1 = 1.0, y2 = y3 = 0. The problem is stiff.

 C

 C     The following coding solves this problem with SLSODE, using

 C     MF = 21 and printing results at t = .4, 4., ..., 4.E10.  It uses

 C     ITOL = 2 and ATOL much smaller for y2 than for y1 or y3 because y2

 C     has much smaller values.  At the end of the run, statistical

 C     quantities of interest are printed.

 C

 C        EXTERNAL  FEX, JEX

 C        INTEGER  IOPT, IOUT, ISTATE, ITASK, ITOL, IWORK(23), LIW, LRW,

 C       *         MF, NEQ

 C        REAL  ATOL(3), RTOL, RWORK(58), T, TOUT, Y(3)

 C        NEQ = 3

 C        Y(1) = 1.

 C        Y(2) = 0.

 C        Y(3) = 0.

 C        T = 0.

 C        TOUT = .4

 C        ITOL = 2

 C        RTOL = 1.E-4

 C        ATOL(1) = 1.E-6

 C        ATOL(2) = 1.E-10

 C        ATOL(3) = 1.E-6

 C        ITASK = 1

 C        ISTATE = 1

 C        IOPT = 0

 C        LRW = 58

 C        LIW = 23

 C        MF = 21

 C        DO 40 IOUT = 1,12

 C          CALL SLSODE (FEX, NEQ, Y, T, TOUT, ITOL, RTOL, ATOL, ITASK,

 C       *               ISTATE, IOPT, RWORK, LRW, IWORK, LIW, JEX, MF)

 C          WRITE(6,20)  T, Y(1), Y(2), Y(3)

 C    20    FORMAT(' At t =',E12.4,'   y =',3E14.6)

 C          IF (ISTATE .LT. 0)  GO TO 80

 C    40    TOUT = TOUT*10.

 C        WRITE(6,60)  IWORK(11), IWORK(12), IWORK(13)

 C    60  FORMAT(/' No. steps =',i4,',  No. f-s =',i4,',  No. J-s =',i4)

 C        STOP

 C    80  WRITE(6,90)  ISTATE

 C    90  FORMAT(///' Error halt.. ISTATE =',I3)

 C        STOP

 C        END

 C

 C        SUBROUTINE  FEX (NEQ, T, Y, YDOT)

 C        INTEGER  NEQ

 C        REAL  T, Y(3), YDOT(3)

 C        YDOT(1) = -.04*Y(1) + 1.E4*Y(2)*Y(3)

 C        YDOT(3) = 3.E7*Y(2)*Y(2)

 C        YDOT(2) = -YDOT(1) - YDOT(3)

 C        RETURN

 C        END

 C

 C        SUBROUTINE  JEX (NEQ, T, Y, ML, MU, PD, NRPD)

 C        INTEGER  NEQ, ML, MU, NRPD

 C        REAL  T, Y(3), PD(NRPD,3)

 C        PD(1,1) = -.04

 C        PD(1,2) = 1.E4*Y(3)

 C        PD(1,3) = 1.E4*Y(2)

 C        PD(2,1) = .04

 C        PD(2,3) = -PD(1,3)

 C        PD(3,2) = 6.E7*Y(2)

 C        PD(2,2) = -PD(1,2) - PD(3,2)

 C        RETURN

 C        END

 C

 C     The output from this program (on a Cray-1 in single precision)

 C     is as follows.

 C

 C     At t =  4.0000e-01   y =  9.851726e-01  3.386406e-05  1.479357e-02

 C     At t =  4.0000e+00   y =  9.055142e-01  2.240418e-05  9.446344e-02

 C     At t =  4.0000e+01   y =  7.158050e-01  9.184616e-06  2.841858e-01

 C     At t =  4.0000e+02   y =  4.504846e-01  3.222434e-06  5.495122e-01

 C     At t =  4.0000e+03   y =  1.831701e-01  8.940379e-07  8.168290e-01

 C     At t =  4.0000e+04   y =  3.897016e-02  1.621193e-07  9.610297e-01

 C     At t =  4.0000e+05   y =  4.935213e-03  1.983756e-08  9.950648e-01

 C     At t =  4.0000e+06   y =  5.159269e-04  2.064759e-09  9.994841e-01

 C     At t =  4.0000e+07   y =  5.306413e-05  2.122677e-10  9.999469e-01

 C     At t =  4.0000e+08   y =  5.494530e-06  2.197825e-11  9.999945e-01

 C     At t =  4.0000e+09   y =  5.129458e-07  2.051784e-12  9.999995e-01

 C     At t =  4.0000e+10   y = -7.170603e-08 -2.868241e-13  1.000000e+00

 C

 C     No. steps = 330,  No. f-s = 405,  No. J-s = 69

 C

 C *Accuracy:

 C     The accuracy of the solution depends on the choice of tolerances

 C     RTOL and ATOL.  Actual (global) errors may exceed these local

 C     tolerances, so choose them conservatively.

 C

 C *Cautions:

 C     The work arrays should not be altered between calls to SLSODE for

 C     the same problem, except possibly for the conditional and optional

 C     inputs.

 C

 C *Portability:

 C     Since NEQ is dimensioned inside SLSODE, some compilers may object

 C     to a call to SLSODE with NEQ a scalar variable.  In this event,

 C     use DIMENSION NEQ(1).  Similar remarks apply to RTOL and ATOL.

 C

 C     Note to Cray users:

 C     For maximum efficiency, use the CFT77 compiler.  Appropriate

 C     compiler optimization directives have been inserted for CFT77.

 C

 C *Reference:

 C     Alan C. Hindmarsh, "ODEPACK, A Systematized Collection of ODE

 C     Solvers," in Scientific Computing, R. S. Stepleman, et al., Eds.

 C     (North-Holland, Amsterdam, 1983), pp. 55-64.

 C

 C *Long Description:

 C     The following complete description of the user interface to

 C     SLSODE consists of four parts:

 C

 C     1.  The call sequence to subroutine SLSODE, which is a driver

 C         routine for the solver.  This includes descriptions of both

 C         the call sequence arguments and user-supplied routines.

 C         Following these descriptions is a description of optional

 C         inputs available through the call sequence, and then a

 C         description of optional outputs in the work arrays.

 C

 C     2.  Descriptions of other routines in the SLSODE package that may

 C         be (optionally) called by the user.  These provide the ability

 C         to alter error message handling, save and restore the internal

 C         COMMON, and obtain specified derivatives of the solution y(t).

 C

 C     3.  Descriptions of COMMON block to be declared in overlay or

 C         similar environments, or to be saved when doing an interrupt

 C         of the problem and continued solution later.

 C

 C     4.  Description of two routines in the SLSODE package, either of

 C         which the user may replace with his own version, if desired.

 C         These relate to the measurement of errors.

 C

 C

 C                         Part 1.  Call Sequence

 C                         ----------------------

 C

 C     Arguments

 C     ---------

 C     The call sequence parameters used for input only are

 C

 C        F, NEQ, TOUT, ITOL, RTOL, ATOL, ITASK, IOPT, LRW, LIW, JAC, MF,

 C

 C     and those used for both input and output are

 C

 C        Y, T, ISTATE.

 C

 C     The work arrays RWORK and IWORK are also used for conditional and

 C     optional inputs and optional outputs.  (The term output here

 C     refers to the return from subroutine SLSODE to the user's calling

 C     program.)

 C

 C     The legality of input parameters will be thoroughly checked on the

 C     initial call for the problem, but not checked thereafter unless a

 C     change in input parameters is flagged by ISTATE = 3 on input.

 C

 C     The descriptions of the call arguments are as follows.

 C

 C     F        The name of the user-supplied subroutine defining the ODE

 C              system.  The system must be put in the first-order form

 C              dy/dt = f(t,y), where f is a vector-valued function of

 C              the scalar t and the vector y. Subroutine F is to compute

 C              the function f. It is to have the form

 C

 C                 SUBROUTINE F (NEQ, T, Y, YDOT)

 C                 REAL T, Y(*), YDOT(*)

 C

 C              where NEQ, T, and Y are input, and the array YDOT =

 C              f(T,Y) is output.  Y and YDOT are arrays of length NEQ.

 C              Subroutine F should not alter Y(1),...,Y(NEQ).  F must be

 C              declared EXTERNAL in the calling program.

 C

 C              Subroutine F may access user-defined quantities in

 C              NEQ(2),... and/or in Y(NEQ(1)+1),..., if NEQ is an array

 C              (dimensioned in F) and/or Y has length exceeding NEQ(1).

 C              See the descriptions of NEQ and Y below.

 C

 C              If quantities computed in the F routine are needed

 C              externally to SLSODE, an extra call to F should be made

 C              for this purpose, for consistent and accurate results.

 C              If only the derivative dy/dt is needed, use SINTDY

 C              instead.

 C

 C     NEQ      The size of the ODE system (number of first-order

 C              ordinary differential equations).  Used only for input.

 C              NEQ may be decreased, but not increased, during the

 C              problem.  If NEQ is decreased (with ISTATE = 3 on input),

 C              the remaining components of Y should be left undisturbed,

 C              if these are to be accessed in F and/or JAC.

 C

 C              Normally, NEQ is a scalar, and it is generally referred

 C              to as a scalar in this user interface description.

 C              However, NEQ may be an array, with NEQ(1) set to the

 C              system size.  (The SLSODE package accesses only NEQ(1).)

 C              In either case, this parameter is passed as the NEQ

 C              argument in all calls to F and JAC.  Hence, if it is an

 C              array, locations NEQ(2),... may be used to store other

 C              integer data and pass it to F and/or JAC.  Subroutines

 C              F and/or JAC must include NEQ in a DIMENSION statement

 C              in that case.

 C

 C     Y        A real array for the vector of dependent variables, of

 C              length NEQ or more.  Used for both input and output on

 C              the first call (ISTATE = 1), and only for output on

 C              other calls.  On the first call, Y must contain the

 C              vector of initial values.  On output, Y contains the

 C              computed solution vector, evaluated at T. If desired,

 C              the Y array may be used for other purposes between

 C              calls to the solver.

 C

 C              This array is passed as the Y argument in all calls to F

 C              and JAC.  Hence its length may exceed NEQ, and locations

 C              Y(NEQ+1),... may be used to store other real data and

 C              pass it to F and/or JAC.  (The SLSODE package accesses

 C              only Y(1),...,Y(NEQ).)

 C

 C     T        The independent variable.  On input, T is used only on

 C              the first call, as the initial point of the integration.

 C              On output, after each call, T is the value at which a

 C              computed solution Y is evaluated (usually the same as

 C              TOUT).  On an error return, T is the farthest point

 C              reached.

 C

 C     TOUT     The next value of T at which a computed solution is

 C              desired.  Used only for input.

 C

 C              When starting the problem (ISTATE = 1), TOUT may be equal

 C              to T for one call, then should not equal T for the next

 C              call.  For the initial T, an input value of TOUT .NE. T

 C              is used in order to determine the direction of the

 C              integration (i.e., the algebraic sign of the step sizes)

 C              and the rough scale of the problem.  Integration in

 C              either direction (forward or backward in T) is permitted.

 C

 C              If ITASK = 2 or 5 (one-step modes), TOUT is ignored

 C              after the first call (i.e., the first call with

 C              TOUT .NE. T).  Otherwise, TOUT is required on every call.

 C

 C              If ITASK = 1, 3, or 4, the values of TOUT need not be

 C              monotone, but a value of TOUT which backs up is limited

 C              to the current internal T interval, whose endpoints are

 C              TCUR - HU and TCUR.  (See "Optional Outputs" below for

 C              TCUR and HU.)

 C

 C

 C     ITOL     An indicator for the type of error control.  See

 C              description below under ATOL.  Used only for input.

 C

 C     RTOL     A relative error tolerance parameter, either a scalar or

 C              an array of length NEQ.  See description below under

 C              ATOL.  Input only.

 C

 C     ATOL     An absolute error tolerance parameter, either a scalar or

 C              an array of length NEQ.  Input only.

 C

 C              The input parameters ITOL, RTOL, and ATOL determine the

 C              error control performed by the solver.  The solver will

 C              control the vector e = (e(i)) of estimated local errors

 C              in Y, according to an inequality of the form

 C

 C                 rms-norm of ( e(i)/EWT(i) ) <= 1,

 C

 C              where

 C

 C                 EWT(i) = RTOL(i)*ABS(Y(i)) + ATOL(i),

 C

 C              and the rms-norm (root-mean-square norm) here is

 C

 C                 rms-norm(v) = SQRT(sum v(i)**2 / NEQ).

 C

 C              Here EWT = (EWT(i)) is a vector of weights which must

 C              always be positive, and the values of RTOL and ATOL

 C              should all be nonnegative.  The following table gives the

 C              types (scalar/array) of RTOL and ATOL, and the

 C              corresponding form of EWT(i).

 C

 C              ITOL    RTOL      ATOL      EWT(i)

 C              ----    ------    ------    -----------------------------

 C              1       scalar    scalar    RTOL*ABS(Y(i)) + ATOL

 C              2       scalar    array     RTOL*ABS(Y(i)) + ATOL(i)

 C              3       array     scalar    RTOL(i)*ABS(Y(i)) + ATOL

 C              4       array     array     RTOL(i)*ABS(Y(i)) + ATOL(i)

 C

 C              When either of these parameters is a scalar, it need not

 C              be dimensioned in the user's calling program.

 C

 C              If none of the above choices (with ITOL, RTOL, and ATOL

 C              fixed throughout the problem) is suitable, more general

 C              error controls can be obtained by substituting

 C              user-supplied routines for the setting of EWT and/or for

 C              the norm calculation.  See Part 4 below.

 C

 C              If global errors are to be estimated by making a repeated

 C              run on the same problem with smaller tolerances, then all

 C              components of RTOL and ATOL (i.e., of EWT) should be

 C              scaled down uniformly.

 C

 C     ITASK    An index specifying the task to be performed.  Input

 C              only.  ITASK has the following values and meanings:

 C              1   Normal computation of output values of y(t) at

 C                  t = TOUT (by overshooting and interpolating).

 C              2   Take one step only and return.

 C              3   Stop at the first internal mesh point at or beyond

 C                  t = TOUT and return.

 C              4   Normal computation of output values of y(t) at

 C                  t = TOUT but without overshooting t = TCRIT.  TCRIT

 C                  must be input as RWORK(1).  TCRIT may be equal to or

 C                  beyond TOUT, but not behind it in the direction of

 C                  integration.  This option is useful if the problem

 C                  has a singularity at or beyond t = TCRIT.

 C              5   Take one step, without passing TCRIT, and return.

 C                  TCRIT must be input as RWORK(1).

 C

 C              Note:  If ITASK = 4 or 5 and the solver reaches TCRIT

 C              (within roundoff), it will return T = TCRIT (exactly) to

 C              indicate this (unless ITASK = 4 and TOUT comes before

 C              TCRIT, in which case answers at T = TOUT are returned

 C              first).

 C

 C     ISTATE   An index used for input and output to specify the state

 C              of the calculation.

 C

 C              On input, the values of ISTATE are as follows:

 C              1   This is the first call for the problem

 C                  (initializations will be done).  See "Note" below.

 C              2   This is not the first call, and the calculation is to

 C                  continue normally, with no change in any input

 C                  parameters except possibly TOUT and ITASK.  (If ITOL,

 C                  RTOL, and/or ATOL are changed between calls with

 C                  ISTATE = 2, the new values will be used but not

 C                  tested for legality.)

 C              3   This is not the first call, and the calculation is to

 C                  continue normally, but with a change in input

 C                  parameters other than TOUT and ITASK.  Changes are

 C                  allowed in NEQ, ITOL, RTOL, ATOL, IOPT, LRW, LIW, MF,

 C                  ML, MU, and any of the optional inputs except H0.

 C                  (See IWORK description for ML and MU.)

 C

 C              Note:  A preliminary call with TOUT = T is not counted as

 C              a first call here, as no initialization or checking of

 C              input is done.  (Such a call is sometimes useful for the

 C              purpose of outputting the initial conditions.)  Thus the

 C              first call for which TOUT .NE. T requires ISTATE = 1 on

 C              input.

 C

 C              On output, ISTATE has the following values and meanings:

 C               1  Nothing was done, as TOUT was equal to T with

 C                  ISTATE = 1 on input.

 C               2  The integration was performed successfully.

 C              -1  An excessive amount of work (more than MXSTEP steps)

 C                  was done on this call, before completing the

 C                  requested task, but the integration was otherwise

 C                  successful as far as T. (MXSTEP is an optional input

 C                  and is normally 500.)  To continue, the user may

 C                  simply reset ISTATE to a value >1 and call again (the

 C                  excess work step counter will be reset to 0).  In

 C                  addition, the user may increase MXSTEP to avoid this

 C                  error return; see "Optional Inputs" below.

 C              -2  Too much accuracy was requested for the precision of

 C                  the machine being used.  This was detected before

 C                  completing the requested task, but the integration

 C                  was successful as far as T. To continue, the

 C                  tolerance parameters must be reset, and ISTATE must

 C                  be set to 3. The optional output TOLSF may be used

 C                  for this purpose.  (Note:  If this condition is

 C                  detected before taking any steps, then an illegal

 C                  input return (ISTATE = -3) occurs instead.)

 C              -3  Illegal input was detected, before taking any

 C                  integration steps.  See written message for details.

 C                  (Note:  If the solver detects an infinite loop of

 C                  calls to the solver with illegal input, it will cause

 C                  the run to stop.)

 C              -4  There were repeated error-test failures on one

 C                  attempted step, before completing the requested task,

 C                  but the integration was successful as far as T.  The

 C                  problem may have a singularity, or the input may be

 C                  inappropriate.

 C              -5  There were repeated convergence-test failures on one

 C                  attempted step, before completing the requested task,

 C                  but the integration was successful as far as T. This

 C                  may be caused by an inaccurate Jacobian matrix, if

 C                  one is being used.

 C              -6  EWT(i) became zero for some i during the integration.

 C                  Pure relative error control (ATOL(i)=0.0) was

 C                  requested on a variable which has now vanished.  The

 C                  integration was successful as far as T.

 C

 C              Note:  Since the normal output value of ISTATE is 2, it

 C              does not need to be reset for normal continuation.  Also,

 C              since a negative input value of ISTATE will be regarded

 C              as illegal, a negative output value requires the user to

 C              change it, and possibly other inputs, before calling the

 C              solver again.

 C

 C     IOPT     An integer flag to specify whether any optional inputs

 C              are being used on this call.  Input only.  The optional

 C              inputs are listed under a separate heading below.

 C              0   No optional inputs are being used.  Default values

 C                  will be used in all cases.

 C              1   One or more optional inputs are being used.

 C

 C     RWORK    A real working array (single precision).  The length of

 C              RWORK must be at least

 C

 C                 20 + NYH*(MAXORD + 1) + 3*NEQ + LWM

 C

 C              where

 C                 NYH = the initial value of NEQ,

 C              MAXORD = 12 (if METH = 1) or 5 (if METH = 2) (unless a

 C                       smaller value is given as an optional input),

 C                 LWM = 0           if MITER = 0,

 C                 LWM = NEQ**2 + 2  if MITER = 1 or 2,

 C                 LWM = NEQ + 2     if MITER = 3, and

 C                 LWM = (2*ML + MU + 1)*NEQ + 2

 C                                   if MITER = 4 or 5.

 C              (See the MF description below for METH and MITER.)

 C

 C              Thus if MAXORD has its default value and NEQ is constant,

 C              this length is:

 C              20 + 16*NEQ                    for MF = 10,

 C              22 + 16*NEQ + NEQ**2           for MF = 11 or 12,

 C              22 + 17*NEQ                    for MF = 13,

 C              22 + 17*NEQ + (2*ML + MU)*NEQ  for MF = 14 or 15,

 C              20 +  9*NEQ                    for MF = 20,

 C              22 +  9*NEQ + NEQ**2           for MF = 21 or 22,

 C              22 + 10*NEQ                    for MF = 23,

 C              22 + 10*NEQ + (2*ML + MU)*NEQ  for MF = 24 or 25.

 C

 C              The first 20 words of RWORK are reserved for conditional

 C              and optional inputs and optional outputs.

 C

 C              The following word in RWORK is a conditional input:

 C              RWORK(1) = TCRIT, the critical value of t which the

 C                         solver is not to overshoot.  Required if ITASK

 C                         is 4 or 5, and ignored otherwise.  See ITASK.

 C

 C     LRW      The length of the array RWORK, as declared by the user.

 C              (This will be checked by the solver.)

 C

 C     IWORK    An integer work array.  Its length must be at least

 C              20       if MITER = 0 or 3 (MF = 10, 13, 20, 23), or

 C              20 + NEQ otherwise (MF = 11, 12, 14, 15, 21, 22, 24, 25).

 C              (See the MF description below for MITER.)  The first few

 C              words of IWORK are used for conditional and optional

 C              inputs and optional outputs.

 C

 C              The following two words in IWORK are conditional inputs:

 C              IWORK(1) = ML   These are the lower and upper half-

 C              IWORK(2) = MU   bandwidths, respectively, of the banded

 C                              Jacobian, excluding the main diagonal.

 C                         The band is defined by the matrix locations

 C                         (i,j) with i - ML <= j <= i + MU. ML and MU

 C                         must satisfy 0 <= ML,MU <= NEQ - 1. These are

 C                         required if MITER is 4 or 5, and ignored

 C                         otherwise.  ML and MU may in fact be the band

 C                         parameters for a matrix to which df/dy is only

 C                         approximately equal.

 C

 C     LIW      The length of the array IWORK, as declared by the user.

 C              (This will be checked by the solver.)

 C

 C     Note:  The work arrays must not be altered between calls to SLSODE

 C     for the same problem, except possibly for the conditional and

 C     optional inputs, and except for the last 3*NEQ words of RWORK.

 C     The latter space is used for internal scratch space, and so is

 C     available for use by the user outside SLSODE between calls, if

 C     desired (but not for use by F or JAC).

 C

 C     JAC      The name of the user-supplied routine (MITER = 1 or 4) to

 C              compute the Jacobian matrix, df/dy, as a function of the

 C              scalar t and the vector y.  (See the MF description below

 C              for MITER.)  It is to have the form

 C

 C                 SUBROUTINE JAC (NEQ, T, Y, ML, MU, PD, NROWPD)

 C                 REAL T, Y(*), PD(NROWPD,*)

 C

 C              where NEQ, T, Y, ML, MU, and NROWPD are input and the

 C              array PD is to be loaded with partial derivatives

 C              (elements of the Jacobian matrix) on output.  PD must be

 C              given a first dimension of NROWPD.  T and Y have the same

 C              meaning as in subroutine F.

 C

 C              In the full matrix case (MITER = 1), ML and MU are

 C              ignored, and the Jacobian is to be loaded into PD in

 C              columnwise manner, with df(i)/dy(j) loaded into PD(i,j).

 C

 C              In the band matrix case (MITER = 4), the elements within

 C              the band are to be loaded into PD in columnwise manner,

 C              with diagonal lines of df/dy loaded into the rows of PD.

 C              Thus df(i)/dy(j) is to be loaded into PD(i-j+MU+1,j).  ML

 C              and MU are the half-bandwidth parameters (see IWORK).

 C              The locations in PD in the two triangular areas which

 C              correspond to nonexistent matrix elements can be ignored

 C              or loaded arbitrarily, as they are overwritten by SLSODE.

 C

 C              JAC need not provide df/dy exactly. A crude approximation

 C              (possibly with a smaller bandwidth) will do.

 C

 C              In either case, PD is preset to zero by the solver, so

 C              that only the nonzero elements need be loaded by JAC.

 C              Each call to JAC is preceded by a call to F with the same

 C              arguments NEQ, T, and Y. Thus to gain some efficiency,

 C              intermediate quantities shared by both calculations may

 C              be saved in a user COMMON block by F and not recomputed

 C              by JAC, if desired.  Also, JAC may alter the Y array, if

 C              desired.  JAC must be declared EXTERNAL in the calling

 C              program.

 C

 C              Subroutine JAC may access user-defined quantities in

 C              NEQ(2),... and/or in Y(NEQ(1)+1),... if NEQ is an array

 C              (dimensioned in JAC) and/or Y has length exceeding

 C              NEQ(1).  See the descriptions of NEQ and Y above.

 C

 C     MF       The method flag.  Used only for input.  The legal values

 C              of MF are 10, 11, 12, 13, 14, 15, 20, 21, 22, 23, 24,

 C              and 25.  MF has decimal digits METH and MITER:

 C                 MF = 10*METH + MITER .

 C

 C              METH indicates the basic linear multistep method:

 C              1   Implicit Adams method.

 C              2   Method based on backward differentiation formulas

 C                  (BDF's).

 C

 C              MITER indicates the corrector iteration method:

 C              0   Functional iteration (no Jacobian matrix is

 C                  involved).

 C              1   Chord iteration with a user-supplied full (NEQ by

 C                  NEQ) Jacobian.

 C              2   Chord iteration with an internally generated

 C                  (difference quotient) full Jacobian (using NEQ

 C                  extra calls to F per df/dy value).

 C              3   Chord iteration with an internally generated

 C                  diagonal Jacobian approximation (using one extra call

 C                  to F per df/dy evaluation).

 C              4   Chord iteration with a user-supplied banded Jacobian.

 C              5   Chord iteration with an internally generated banded

 C                  Jacobian (using ML + MU + 1 extra calls to F per

 C                  df/dy evaluation).

 C

 C              If MITER = 1 or 4, the user must supply a subroutine JAC

 C              (the name is arbitrary) as described above under JAC.

 C              For other values of MITER, a dummy argument can be used.

 C

 C     Optional Inputs

 C     ---------------

 C     The following is a list of the optional inputs provided for in the

 C     call sequence.  (See also Part 2.)  For each such input variable,

 C     this table lists its name as used in this documentation, its

 C     location in the call sequence, its meaning, and the default value.

 C     The use of any of these inputs requires IOPT = 1, and in that case

 C     all of these inputs are examined.  A value of zero for any of

 C     these optional inputs will cause the default value to be used.

 C     Thus to use a subset of the optional inputs, simply preload

 C     locations 5 to 10 in RWORK and IWORK to 0.0 and 0 respectively,

 C     and then set those of interest to nonzero values.

 C

 C     Name    Location   Meaning and default value

 C     ------  ---------  -----------------------------------------------

 C     H0      RWORK(5)   Step size to be attempted on the first step.

 C                        The default value is determined by the solver.

 C     HMAX    RWORK(6)   Maximum absolute step size allowed.  The

 C                        default value is infinite.

 C     HMIN    RWORK(7)   Minimum absolute step size allowed.  The

 C                        default value is 0.  (This lower bound is not

 C                        enforced on the final step before reaching

 C                        TCRIT when ITASK = 4 or 5.)

 C     MAXORD  IWORK(5)   Maximum order to be allowed.  The default value

 C                        is 12 if METH = 1, and 5 if METH = 2. (See the

 C                        MF description above for METH.)  If MAXORD

 C                        exceeds the default value, it will be reduced

 C                        to the default value.  If MAXORD is changed

 C                        during the problem, it may cause the current

 C                        order to be reduced.

 C     MXSTEP  IWORK(6)   Maximum number of (internally defined) steps

 C                        allowed during one call to the solver.  The

 C                        default value is 500.

 C     MXHNIL  IWORK(7)   Maximum number of messages printed (per

 C                        problem) warning that T + H = T on a step

 C                        (H = step size).  This must be positive to

 C                        result in a nondefault value.  The default

 C                        value is 10.

 C

 C     Optional Outputs

 C     ----------------

 C     As optional additional output from SLSODE, the variables listed

 C     below are quantities related to the performance of SLSODE which

 C     are available to the user.  These are communicated by way of the

 C     work arrays, but also have internal mnemonic names as shown.

 C     Except where stated otherwise, all of these outputs are defined on

 C     any successful return from SLSODE, and on any return with ISTATE =

 C     -1, -2, -4, -5, or -6.  On an illegal input return (ISTATE = -3),

 C     they will be unchanged from their existing values (if any), except

 C     possibly for TOLSF, LENRW, and LENIW.  On any error return,

 C     outputs relevant to the error will be defined, as noted below.

 C

 C     Name   Location   Meaning

 C     -----  ---------  ------------------------------------------------

 C     HU     RWORK(11)  Step size in t last used (successfully).

 C     HCUR   RWORK(12)  Step size to be attempted on the next step.

 C     TCUR   RWORK(13)  Current value of the independent variable which

 C                       the solver has actually reached, i.e., the

 C                       current internal mesh point in t. On output,

 C                       TCUR will always be at least as far as the

 C                       argument T, but may be farther (if interpolation

 C                       was done).

 C     TOLSF  RWORK(14)  Tolerance scale factor, greater than 1.0,

 C                       computed when a request for too much accuracy

 C                       was detected (ISTATE = -3 if detected at the

 C                       start of the problem, ISTATE = -2 otherwise).

 C                       If ITOL is left unaltered but RTOL and ATOL are

 C                       uniformly scaled up by a factor of TOLSF for the

 C                       next call, then the solver is deemed likely to

 C                       succeed.  (The user may also ignore TOLSF and

 C                       alter the tolerance parameters in any other way

 C                       appropriate.)

 C     NST    IWORK(11)  Number of steps taken for the problem so far.

 C     NFE    IWORK(12)  Number of F evaluations for the problem so far.

 C     NJE    IWORK(13)  Number of Jacobian evaluations (and of matrix LU

 C                       decompositions) for the problem so far.

 C     NQU    IWORK(14)  Method order last used (successfully).

 C     NQCUR  IWORK(15)  Order to be attempted on the next step.

 C     IMXER  IWORK(16)  Index of the component of largest magnitude in

 C                       the weighted local error vector ( e(i)/EWT(i) ),

 C                       on an error return with ISTATE = -4 or -5.

 C     LENRW  IWORK(17)  Length of RWORK actually required.  This is

 C                       defined on normal returns and on an illegal

 C                       input return for insufficient storage.

 C     LENIW  IWORK(18)  Length of IWORK actually required.  This is

 C                       defined on normal returns and on an illegal

 C                       input return for insufficient storage.

 C

 C     The following two arrays are segments of the RWORK array which may

 C     also be of interest to the user as optional outputs.  For each

 C     array, the table below gives its internal name, its base address

 C     in RWORK, and its description.

 C

 C     Name  Base address  Description

 C     ----  ------------  ----------------------------------------------

 C     YH    21            The Nordsieck history array, of size NYH by

 C                         (NQCUR + 1), where NYH is the initial value of

 C                         NEQ.  For j = 0,1,...,NQCUR, column j + 1 of

 C                         YH contains HCUR**j/factorial(j) times the jth

 C                         derivative of the interpolating polynomial

 C                         currently representing the solution, evaluated

 C                         at t = TCUR.

 C     ACOR  LENRW-NEQ+1   Array of size NEQ used for the accumulated

 C                         corrections on each step, scaled on output to

 C                         represent the estimated local error in Y on

 C                         the last step.  This is the vector e in the

 C                         description of the error control.  It is

 C                         defined only on successful return from SLSODE.

 C

 C

 C                    Part 2.  Other Callable Routines

 C                    --------------------------------

 C

 C     The following are optional calls which the user may make to gain

 C     additional capabilities in conjunction with SLSODE.

 C

 C     Form of call              Function

 C     ------------------------  ----------------------------------------

 C     CALL XSETUN(LUN)          Set the logical unit number, LUN, for

 C                               output of messages from SLSODE, if the

 C                               default is not desired.  The default

 C                               value of LUN is 6. This call may be made

 C                               at any time and will take effect

 C                               immediately.

 C     CALL XSETF(MFLAG)         Set a flag to control the printing of

 C                               messages by SLSODE.  MFLAG = 0 means do

 C                               not print.  (Danger:  this risks losing

 C                               valuable information.)  MFLAG = 1 means

 C                               print (the default).  This call may be

 C                               made at any time and will take effect

 C                               immediately.

 C     CALL SSRCOM(RSAV,ISAV,JOB)  Saves and restores the contents of the

 C                               internal COMMON blocks used by SLSODE

 C                               (see Part 3 below).  RSAV must be a

 C                               real array of length 218 or more, and

 C                               ISAV must be an integer array of length

 C                               37 or more.  JOB = 1 means save COMMON

 C                               into RSAV/ISAV.  JOB = 2 means restore

 C                               COMMON from same.  SSRCOM is useful if

 C                               one is interrupting a run and restarting

 C                               later, or alternating between two or

 C                               more problems solved with SLSODE.

 C     CALL SINTDY(,,,,,)        Provide derivatives of y, of various

 C     (see below)               orders, at a specified point t, if

 C                               desired.  It may be called only after a

 C                               successful return from SLSODE.  Detailed

 C                               instructions follow.

 C

 C     Detailed instructions for using SINTDY

 C     --------------------------------------

 C     The form of the CALL is:

 C

 C           CALL SINTDY (T, K, RWORK(21), NYH, DKY, IFLAG)

 C

 C     The input parameters are:

 C

 C     T          Value of independent variable where answers are

 C                desired (normally the same as the T last returned by

 C                SLSODE).  For valid results, T must lie between

 C                TCUR - HU and TCUR.  (See "Optional Outputs" above

 C                for TCUR and HU.)

 C     K          Integer order of the derivative desired.  K must

 C                satisfy 0 <= K <= NQCUR, where NQCUR is the current

 C                order (see "Optional Outputs").  The capability

 C                corresponding to K = 0, i.e., computing y(t), is

 C                already provided by SLSODE directly.  Since

 C                NQCUR >= 1, the first derivative dy/dt is always

 C                available with SINTDY.

 C     RWORK(21)  The base address of the history array YH.

 C     NYH        Column length of YH, equal to the initial value of NEQ.

 C

 C     The output parameters are:

 C

 C     DKY        Real array of length NEQ containing the computed value

 C                of the Kth derivative of y(t).

 C     IFLAG      Integer flag, returned as 0 if K and T were legal,

 C                -1 if K was illegal, and -2 if T was illegal.

 C                On an error return, a message is also written.

 C

 C

 C                          Part 3.  Common Blocks

 C                          ----------------------

 C

 C     If SLSODE is to be used in an overlay situation, the user must

 C     declare, in the primary overlay, the variables in:

 C     (1) the call sequence to SLSODE,

 C     (2) the internal COMMON block /SLS001/, of length 255

 C         (218 single precision words followed by 37 integer words).

 C

 C     If SLSODE is used on a system in which the contents of internal

 C     COMMON blocks are not preserved between calls, the user should

 C     declare the above COMMON block in his main program to insure that

 C     its contents are preserved.

 C

 C     If the solution of a given problem by SLSODE is to be interrupted

 C     and then later continued, as when restarting an interrupted run or

 C     alternating between two or more problems, the user should save,

 C     following the return from the last SLSODE call prior to the

 C     interruption, the contents of the call sequence variables and the

 C     internal COMMON block, and later restore these values before the

 C     next SLSODE call for that problem.   In addition, if XSETUN and/or

 C     XSETF was called for non-default handling of error messages, then

 C     these calls must be repeated.  To save and restore the COMMON

 C     block, use subroutine SSRCOM (see Part 2 above).

 C

 C

 C              Part 4.  Optionally Replaceable Solver Routines

 C              -----------------------------------------------

 C

 C     Below are descriptions of two routines in the SLSODE package which

 C     relate to the measurement of errors.  Either routine can be

 C     replaced by a user-supplied version, if desired.  However, since

 C     such a replacement may have a major impact on performance, it

 C     should be done only when absolutely necessary, and only with great

 C     caution.  (Note:  The means by which the package version of a

 C     routine is superseded by the user's version may be system-

 C     dependent.)

 C

 C     SEWSET

 C     ------

 C     The following subroutine is called just before each internal

 C     integration step, and sets the array of error weights, EWT, as

 C     described under ITOL/RTOL/ATOL above:

 C

 C           SUBROUTINE SEWSET (NEQ, ITOL, RTOL, ATOL, YCUR, EWT)

 C

 C     where NEQ, ITOL, RTOL, and ATOL are as in the SLSODE call

 C     sequence, YCUR contains the current dependent variable vector,

 C     and EWT is the array of weights set by SEWSET.

 C

 C     If the user supplies this subroutine, it must return in EWT(i)

 C     (i = 1,...,NEQ) a positive quantity suitable for comparing errors

 C     in Y(i) to.  The EWT array returned by SEWSET is passed to the

 C     SVNORM routine (see below), and also used by SLSODE in the

 C     computation of the optional output IMXER, the diagonal Jacobian

 C     approximation, and the increments for difference quotient

 C     Jacobians.

 C

 C     In the user-supplied version of SEWSET, it may be desirable to use

 C     the current values of derivatives of y. Derivatives up to order NQ

 C     are available from the history array YH, described above under

 C     optional outputs.  In SEWSET, YH is identical to the YCUR array,

 C     extended to NQ + 1 columns with a column length of NYH and scale

 C     factors of H**j/factorial(j).  On the first call for the problem,

 C     given by NST = 0, NQ is 1 and H is temporarily set to 1.0.

 C     NYH is the initial value of NEQ.  The quantities NQ, H, and NST

 C     can be obtained by including in SEWSET the statements:

 C           REAL RLS

 C           COMMON /SLS001/ RLS(218),ILS(37)

 C           NQ = ILS(33)

 C           NST = ILS(34)

 C           H = RLS(212)

 C     Thus, for example, the current value of dy/dt can be obtained as

 C     YCUR(NYH+i)/H (i=1,...,NEQ) (and the division by H is unnecessary

 C     when NST = 0).

 C

 C     SVNORM

 C     ------

 C     SVNORM is a real function routine which computes the weighted

 C     root-mean-square norm of a vector v:

 C

 C        d = SVNORM (n, v, w)

 C

 C     where:

 C     n = the length of the vector,

 C     v = real array of length n containing the vector,

 C     w = real array of length n containing weights,

 C     d = SQRT( (1/n) * sum(v(i)*w(i))**2 ).

 C

 C     SVNORM is called with n = NEQ and with w(i) = 1.0/EWT(i), where

 C     EWT is as set by subroutine SEWSET.

 C

 C     If the user supplies this function, it should return a nonnegative

 C     value of SVNORM suitable for use in the error control in SLSODE.

 C     None of the arguments should be altered by SVNORM.  For example, a

 C     user-supplied SVNORM routine might:

 C     - Substitute a max-norm of (v(i)*w(i)) for the rms-norm, or

 C     - Ignore some components of v in the norm, with the effect of

 C       suppressing the error control on those components of Y.

 C  ---------------------------------------------------------------------

 C***ROUTINES CALLED  SEWSET, SINTDY, R1MACH, SSTODE, SVNORM, XERRWV

 C***COMMON BLOCKS    SLS001

 C***REVISION HISTORY  (YYYYMMDD)

 C 19791129  DATE WRITTEN

 C 19791213  Minor changes to declarations; DELP init. in STODE.

 C 19800118  Treat NEQ as array; integer declarations added throughout;

 C           minor changes to prologue.

 C 19800306  Corrected TESCO(1,NQP1) setting in CFODE.

 C 19800519  Corrected access of YH on forced order reduction;

 C           numerous corrections to prologues and other comments.

 C 19800617  In main driver, added loading of SQRT(UROUND) in RWORK;

 C           minor corrections to main prologue.

 C 19800923  Added zero initialization of HU and NQU.

 C 19801218  Revised XERRWV routine; minor corrections to main prologue.

 C 19810401  Minor changes to comments and an error message.

 C 19810814  Numerous revisions: replaced EWT by 1/EWT; used flags

 C           JCUR, ICF, IERPJ, IERSL between STODE and subordinates;

 C           added tuning parameters CCMAX, MAXCOR, MSBP, MXNCF;

 C           reorganized returns from STODE; reorganized type decls.;

 C           fixed message length in XERRWV; changed default LUNIT to 6;

 C           changed Common lengths; changed comments throughout.

 C 19870330  Major update by ACH: corrected comments throughout;

 C           removed TRET from Common; rewrote EWSET with 4 loops;

 C           fixed t test in INTDY; added Cray directives in STODE;

 C           in STODE, fixed DELP init. and logic around PJAC call;

 C           combined routines to save/restore Common;

 C           passed LEVEL = 0 in error message calls (except run abort).

 C 19890426  Modified prologue to SLATEC/LDOC format.  (FNF)

 C 19890501  Many improvements to prologue.  (FNF)

 C 19890503  A few final corrections to prologue.  (FNF)

 C 19890504  Minor cosmetic changes.  (FNF)

 C 19890510  Corrected description of Y in Arguments section.  (FNF)

 C 19890517  Minor corrections to prologue.  (FNF)

 C 19920514  Updated with prologue edited 891025 by G. Shaw for manual.

 C 19920515  Converted source lines to upper case.  (FNF)

 C 19920603  Revised XERRWV calls using mixed upper-lower case.  (ACH)

 C 19920616  Revised prologue comment regarding CFT.  (ACH)

 C 19921116  Revised prologue comments regarding Common.  (ACH).

 C 19930326  Added comment about non-reentrancy.  (FNF)

 C 19930723  Changed R1MACH to RUMACH. (FNF)

 C 19930801  Removed ILLIN and NTREP from Common (affects driver logic);

 C           minor changes to prologue and internal comments;

 C           changed Hollerith strings to quoted strings;

 C           changed internal comments to mixed case;

 C           replaced XERRWV with new version using character type;

 C           changed dummy dimensions from 1 to *. (ACH)

 C 19930809  Changed to generic intrinsic names; changed names of

 C           subprograms and Common blocks to SLSODE etc. (ACH)

 C 19930929  Eliminated use of REAL intrinsic; other minor changes. (ACH)

 C 20010412  Removed all 'own' variables from Common block /SLS001/

 C           (affects declarations in 6 routines). (ACH)

 C 20010509  Minor corrections to prologue. (ACH)

 C 20031105  Restored 'own' variables to Common block /SLS001/, to

 C           enable interrupt/restart feature. (ACH)

 C 20031112  Added SAVE statements for data-loaded constants.

 C

 C***  END PROLOGUE  SLSODE

 C

 C*Internal Notes:

 C

 C Other Routines in the SLSODE Package.

 C

 C In addition to Subroutine SLSODE, the SLSODE package includes the

 C following subroutines and function routines:

 C  SINTDY   computes an interpolated value of the y vector at t = TOUT.

 C  SSTODE   is the core integrator, which does one step of the

 C           integration and the associated error control.

 C  SCFODE   sets all method coefficients and test constants.

 C  SPREPJ   computes and preprocesses the Jacobian matrix J = df/dy

 C           and the Newton iteration matrix P = I - h*l0*J.

 C  SSOLSY   manages solution of linear system in chord iteration.

 C  SEWSET   sets the error weight vector EWT before each step.

 C  SVNORM   computes the weighted R.M.S. norm of a vector.

 C  SSRCOM   is a user-callable routine to save and restore

 C           the contents of the internal Common block.

 C  DGETRF AND DGETRS   ARE ROUTINES FROM LAPACK FOR SOLVING FULL

 C           SYSTEMS OF LINEAR ALGEBRAIC EQUATIONS.

 C  DGBTRF AND DGBTRS   ARE ROUTINES FROM LAPACK FOR SOLVING BANDED

 C           LINEAR SYSTEMS.

 C  R1MACH   computes the unit roundoff in a machine-independent manner.

 C  XERRWV, XSETUN, XSETF, IXSAV, IUMACH   handle the printing of all

 C           error messages and warnings.  XERRWV is machine-dependent.

 C Note: SVNORM, R1MACH, IXSAV, and IUMACH are function routines.

 C All the others are subroutines.

 C

 C**End

 C

 C  Declare externals.

       EXTERNAL sprepj, ssolsy

       REAL R1MACH, SVNORM

 C

 C  Declare all other variables.

       INTEGER INIT, MXSTEP, MXHNIL, NHNIL, NSLAST, NYH,

      1   ialth, ipup, lmax, meo, nqnyh, nslp,

      1   icf, ierpj, iersl, jcur, jstart, kflag, l,

      2   lyh, lewt, lacor, lsavf, lwm, liwm, meth, miter,

      3   maxord, maxcor, msbp, mxncf, n, nq, nst, nfe, nje, nqu

       INTEGER I, I1, I2, IFLAG, IMXER, KGO, LF0,

      1   leniw, lenrw, lenwm, ml, mord, mu, mxhnl0, mxstp0

       REAL CONIT, CRATE, EL, ELCO, HOLD, RMAX, TESCO,

      1   ccmax, el0, h, hmin, hmxi, hu, rc, tn, uround

       REAL ATOLI, AYI, BIG, EWTI, H0, HMAX, HMX, RH, RTOLI,

      1   tcrit, tdist, tnext, tol, tolsf, tp, SIZE, sum, w0

       dimension mord(2)

       LOGICAL IHIT

       CHARACTER*80 MSG

       SAVE mord, mxstp0, mxhnl0

 C-----------------------------------------------------------------------

 C The following internal Common block contains

 C (a) variables which are local to any subroutine but whose values must

 C     be preserved between calls to the routine ("own" variables), and

 C (b) variables which are communicated between subroutines.

 C The block SLS001 is declared in subroutines SLSODE, SINTDY, SSTODE,

 C SPREPJ, and SSOLSY.

 C Groups of variables are replaced by dummy arrays in the Common

 C declarations in routines where those variables are not used.

 C-----------------------------------------------------------------------

       COMMON /sls001/ conit, crate, el(13), elco(13,12),

      1   hold, rmax, tesco(3,12),

      1   ccmax, el0, h, hmin, hmxi, hu, rc, tn, uround,

      2   init, mxstep, mxhnil, nhnil, nslast, nyh,

      3   ialth, ipup, lmax, meo, nqnyh, nslp,

      3   icf, ierpj, iersl, jcur, jstart, kflag, l,

      4   lyh, lewt, lacor, lsavf, lwm, liwm, meth, miter,

      5   maxord, maxcor, msbp, mxncf, n, nq, nst, nfe, nje, nqu

 C

       DATA  mord(1),mord(2)/12,5/, mxstp0/500/, mxhnl0/10/

 C-----------------------------------------------------------------------

 C Block A.

 C This code block is executed on every call.

 C It tests ISTATE and ITASK for legality and branches appropriately.

 C If ISTATE .GT. 1 but the flag INIT shows that initialization has

 C not yet been done, an error return occurs.

 C If ISTATE = 1 and TOUT = T, return immediately.

 C-----------------------------------------------------------------------

 C

 C***FIRST EXECUTABLE STATEMENT  SLSODE

       IF (istate .LT. 1 .OR. istate .GT. 3) GO TO 601

       IF (itask .LT. 1 .OR. itask .GT. 5) GO TO 602

       IF (istate .EQ. 1) GO TO 10

       IF (init .EQ. 0) GO TO 603

       IF (istate .EQ. 2) GO TO 200

       GO TO 20

  10   init = 0

       IF (tout .EQ. t) RETURN

 C-----------------------------------------------------------------------

 C Block B.

 C The next code block is executed for the initial call (ISTATE = 1),

 C or for a continuation call with parameter changes (ISTATE = 3).

 C It contains checking of all inputs and various initializations.

 C

 C First check legality of the non-optional inputs NEQ, ITOL, IOPT,

 C MF, ML, and MU.

 C-----------------------------------------------------------------------

  20   IF (neq(1) .LE. 0) GO TO 604

       IF (istate .EQ. 1) GO TO 25

       IF (neq(1) .GT. n) GO TO 605

  25   n = neq(1)

       IF (itol .LT. 1 .OR. itol .GT. 4) GO TO 606

       IF (iopt .LT. 0 .OR. iopt .GT. 1) GO TO 607

       meth = mf/10

       miter = mf - 10*meth

       IF (meth .LT. 1 .OR. meth .GT. 2) GO TO 608

       IF (miter .LT. 0 .OR. miter .GT. 5) GO TO 608

       IF (miter .LE. 3) GO TO 30

       ml = iwork(1)

       mu = iwork(2)

       IF (ml .LT. 0 .OR. ml .GE. n) GO TO 609

       IF (mu .LT. 0 .OR. mu .GE. n) GO TO 610

  30   CONTINUE

 C Next process and check the optional inputs. --------------------------

       IF (iopt .EQ. 1) GO TO 40

       maxord = mord(meth)

       mxstep = mxstp0

       mxhnil = mxhnl0

       IF (istate .EQ. 1) h0 = 0.0e0

       hmxi = 0.0e0

       hmin = 0.0e0

       GO TO 60

  40   maxord = iwork(5)

       IF (maxord .LT. 0) GO TO 611

       IF (maxord .EQ. 0) maxord = 100

       maxord = min(maxord,mord(meth))

       mxstep = iwork(6)

       IF (mxstep .LT. 0) GO TO 612

       IF (mxstep .EQ. 0) mxstep = mxstp0

       mxhnil = iwork(7)

       IF (mxhnil .LT. 0) GO TO 613

       IF (mxhnil .EQ. 0) mxhnil = mxhnl0

       IF (istate .NE. 1) GO TO 50

       h0 = rwork(5)

       IF ((tout - t)*h0 .LT. 0.0e0) GO TO 614

  50   hmax = rwork(6)

       IF (hmax .LT. 0.0e0) GO TO 615

       hmxi = 0.0e0

       IF (hmax .GT. 0.0e0) hmxi = 1.0e0/hmax

       hmin = rwork(7)

       IF (hmin .LT. 0.0e0) GO TO 616

 C-----------------------------------------------------------------------

 C Set work array pointers and check lengths LRW and LIW.

 C Pointers to segments of RWORK and IWORK are named by prefixing L to

 C the name of the segment.  E.g., the segment YH starts at RWORK(LYH).

 C Segments of RWORK (in order) are denoted  YH, WM, EWT, SAVF, ACOR.

 C-----------------------------------------------------------------------

  60   lyh = 21

       IF (istate .EQ. 1) nyh = n

       lwm = lyh + (maxord + 1)*nyh

       IF (miter .EQ. 0) lenwm = 0

       IF (miter .EQ. 1 .OR. miter .EQ. 2) lenwm = n*n + 2

       IF (miter .EQ. 3) lenwm = n + 2

       IF (miter .GE. 4) lenwm = (2*ml + mu + 1)*n + 2

       lewt = lwm + lenwm

       lsavf = lewt + n

       lacor = lsavf + n

       lenrw = lacor + n - 1

       iwork(17) = lenrw

       liwm = 1

       leniw = 20 + n

       IF (miter .EQ. 0 .OR. miter .EQ. 3) leniw = 20

       iwork(18) = leniw

       IF (lenrw .GT. lrw) GO TO 617

       IF (leniw .GT. liw) GO TO 618

 C Check RTOL and ATOL for legality. ------------------------------------

       rtoli = rtol(1)

       atoli = atol(1)

       DO 70 i = 1,n

         IF (itol .GE. 3) rtoli = rtol(i)

         IF (itol .EQ. 2 .OR. itol .EQ. 4) atoli = atol(i)

         IF (rtoli .LT. 0.0e0) GO TO 619

         IF (atoli .LT. 0.0e0) GO TO 620

  70     CONTINUE

       IF (istate .EQ. 1) GO TO 100

 C If ISTATE = 3, set flag to signal parameter changes to SSTODE. -------

       jstart = -1

       IF (nq .LE. maxord) GO TO 90

 C MAXORD was reduced below NQ.  Copy YH(*,MAXORD+2) into SAVF. ---------

       DO 80 i = 1,n

  80     rwork(i+lsavf-1) = rwork(i+lwm-1)

 C Reload WM(1) = RWORK(LWM), since LWM may have changed. ---------------

  90   IF (miter .GT. 0) rwork(lwm) = sqrt(uround)

       IF (n .EQ. nyh) GO TO 200

 C NEQ was reduced.  Zero part of YH to avoid undefined references. -----

       i1 = lyh + l*nyh

       i2 = lyh + (maxord + 1)*nyh - 1

       IF (i1 .GT. i2) GO TO 200

       DO 95 i = i1,i2

  95     rwork(i) = 0.0e0

       GO TO 200

 C-----------------------------------------------------------------------

 C Block C.

 C The next block is for the initial call only (ISTATE = 1).

 C It contains all remaining initializations, the initial call to F,

 C and the calculation of the initial step size.

 C The error weights in EWT are inverted after being loaded.

 C-----------------------------------------------------------------------

  100  uround = r1mach(4)

       tn = t

       IF (itask .NE. 4 .AND. itask .NE. 5) GO TO 110

       tcrit = rwork(1)

       IF ((tcrit - tout)*(tout - t) .LT. 0.0e0) GO TO 625

       IF (h0 .NE. 0.0e0 .AND. (t + h0 - tcrit)*h0 .GT. 0.0e0)

      1   h0 = tcrit - t

  110  jstart = 0

       IF (miter .GT. 0) rwork(lwm) = sqrt(uround)

       nhnil = 0

       nst = 0

       nje = 0

       nslast = 0

       hu = 0.0e0

       nqu = 0

       ccmax = 0.3e0

       maxcor = 3

       msbp = 20

       mxncf = 10

 C Initial call to F.  (LF0 points to YH(*,2).) -------------------------

       lf0 = lyh + nyh

       CALL f (neq, t, y, rwork(lf0))

       nfe = 1

 C Load the initial value vector in YH. ---------------------------------

       DO 115 i = 1,n

  115    rwork(i+lyh-1) = y(i)

 C Load and invert the EWT array.  (H is temporarily set to 1.0.) -------

       nq = 1

       h = 1.0e0

       CALL sewset (n, itol, rtol, atol, rwork(lyh), rwork(lewt))

       DO 120 i = 1,n

         IF (rwork(i+lewt-1) .LE. 0.0e0) GO TO 621

  120    rwork(i+lewt-1) = 1.0e0/rwork(i+lewt-1)

 C-----------------------------------------------------------------------

 C The coding below computes the step size, H0, to be attempted on the

 C first step, unless the user has supplied a value for this.

 C First check that TOUT - T differs significantly from zero.

 C A scalar tolerance quantity TOL is computed, as MAX(RTOL(I))

 C if this is positive, or MAX(ATOL(I)/ABS(Y(I))) otherwise, adjusted

 C so as to be between 100*UROUND and 1.0E-3.

 C Then the computed value H0 is given by..

 C                                      NEQ

 C   H0**2 = TOL / ( w0**-2 + (1/NEQ) * SUM ( f(i)/ywt(i) )**2  )

 C                                       1

 C where   w0     = MAX ( ABS(T), ABS(TOUT) ),

 C         f(i)   = i-th component of initial value of f,

 C         ywt(i) = EWT(i)/TOL  (a weight for y(i)).

 C The sign of H0 is inferred from the initial values of TOUT and T.

 C-----------------------------------------------------------------------

       IF (h0 .NE. 0.0e0) GO TO 180

       tdist = abs(tout - t)

       w0 = max(abs(t),abs(tout))

       IF (tdist .LT. 2.0e0*uround*w0) GO TO 622

       tol = rtol(1)

       IF (itol .LE. 2) GO TO 140

       DO 130 i = 1,n

  130    tol = max(tol,rtol(i))

  140  IF (tol .GT. 0.0e0) GO TO 160

       atoli = atol(1)

       DO 150 i = 1,n

         IF (itol .EQ. 2 .OR. itol .EQ. 4) atoli = atol(i)

         ayi = abs(y(i))

         IF (ayi .NE. 0.0e0) tol = max(tol,atoli/ayi)

  150    CONTINUE

  160  tol = max(tol,100.0e0*uround)

       tol = min(tol,0.001e0)

       sum = svnorm(n, rwork(lf0), rwork(lewt))

       sum = 1.0e0/(tol*w0*w0) + tol*sum**2

       h0 = 1.0e0/sqrt(sum)

       h0 = min(h0,tdist)

       h0 = sign(h0,tout-t)

 C Adjust H0 if necessary to meet HMAX bound. ---------------------------

  180  rh = abs(h0)*hmxi

       IF (rh .GT. 1.0e0) h0 = h0/rh

 C Load H with H0 and scale YH(*,2) by H0. ------------------------------

       h = h0

       DO 190 i = 1,n

  190    rwork(i+lf0-1) = h0*rwork(i+lf0-1)

       GO TO 270

 C-----------------------------------------------------------------------

 C Block D.

 C The next code block is for continuation calls only (ISTATE = 2 or 3)

 C and is to check stop conditions before taking a step.

 C-----------------------------------------------------------------------

  200  nslast = nst

       GO TO (210, 250, 220, 230, 240), itask

  210  IF ((tn - tout)*h .LT. 0.0e0) GO TO 250

       CALL sintdy (tout, 0, rwork(lyh), nyh, y, iflag)

       IF (iflag .NE. 0) GO TO 627

       t = tout

       GO TO 420

  220  tp = tn - hu*(1.0e0 + 100.0e0*uround)

       IF ((tp - tout)*h .GT. 0.0e0) GO TO 623

       IF ((tn - tout)*h .LT. 0.0e0) GO TO 250

       GO TO 400

  230  tcrit = rwork(1)

       IF ((tn - tcrit)*h .GT. 0.0e0) GO TO 624

       IF ((tcrit - tout)*h .LT. 0.0e0) GO TO 625

       IF ((tn - tout)*h .LT. 0.0e0) GO TO 245

       CALL sintdy (tout, 0, rwork(lyh), nyh, y, iflag)

       IF (iflag .NE. 0) GO TO 627

       t = tout

       GO TO 420

  240  tcrit = rwork(1)

       IF ((tn - tcrit)*h .GT. 0.0e0) GO TO 624

  245  hmx = abs(tn) + abs(h)

       ihit = abs(tn - tcrit) .LE. 100.0e0*uround*hmx

       IF (ihit) GO TO 400

       tnext = tn + h*(1.0e0 + 4.0e0*uround)

       IF ((tnext - tcrit)*h .LE. 0.0e0) GO TO 250

       h = (tcrit - tn)*(1.0e0 - 4.0e0*uround)

       IF (istate .EQ. 2) jstart = -2

 C-----------------------------------------------------------------------

 C Block E.

 C The next block is normally executed for all calls and contains

 C the call to the one-step core integrator SSTODE.

 C

 C This is a looping point for the integration steps.

 C

 C First check for too many steps being taken, update EWT (if not at

 C start of problem), check for too much accuracy being requested, and

 C check for H below the roundoff level in T.

 C-----------------------------------------------------------------------

  250  CONTINUE

       IF ((nst-nslast) .GE. mxstep) GO TO 500

       CALL sewset (n, itol, rtol, atol, rwork(lyh), rwork(lewt))

       DO 260 i = 1,n

         IF (rwork(i+lewt-1) .LE. 0.0e0) GO TO 510

  260    rwork(i+lewt-1) = 1.0e0/rwork(i+lewt-1)

  270  tolsf = uround*svnorm(n, rwork(lyh), rwork(lewt))

       IF (tolsf .LE. 1.0e0) GO TO 280

       tolsf = tolsf*2.0e0

       IF (nst .EQ. 0) GO TO 626

       GO TO 520

  280  IF ((tn + h) .NE. tn) GO TO 290

       nhnil = nhnil + 1

       IF (nhnil .GT. mxhnil) GO TO 290

       msg = 'SLSODE-  Warning..internal T (=R1) and H (=R2) are'

       CALL xerrwv (msg, 50, 101, 0, 0, 0, 0, 0, 0.0e0, 0.0e0)

       msg='      such that in the machine, T + H = T on the next step  '

       CALL xerrwv (msg, 60, 101, 0, 0, 0, 0, 0, 0.0e0, 0.0e0)

       msg = '      (H = step size). Solver will continue anyway'

       CALL xerrwv (msg, 50, 101, 0, 0, 0, 0, 2, tn, h)

       IF (nhnil .LT. mxhnil) GO TO 290

       msg = 'SLSODE-  Above warning has been issued I1 times.  '

       CALL xerrwv (msg, 50, 102, 0, 0, 0, 0, 0, 0.0e0, 0.0e0)

       msg = '      It will not be issued again for this problem'

       CALL xerrwv (msg, 50, 102, 0, 1, mxhnil, 0, 0, 0.0e0, 0.0e0)

  290  CONTINUE

 C-----------------------------------------------------------------------

 C  CALL SSTODE(NEQ,Y,YH,NYH,YH,EWT,SAVF,ACOR,WM,IWM,F,JAC,SPREPJ,SSOLSY)

 C-----------------------------------------------------------------------

       CALL sstode (neq, y, rwork(lyh), nyh, rwork(lyh), rwork(lewt),

      1   rwork(lsavf), rwork(lacor), rwork(lwm), iwork(liwm),

      2   f, jac, sprepj, ssolsy)

       kgo = 1 - kflag

       GO TO (300, 530, 540), kgo

 C-----------------------------------------------------------------------

 C Block F.

 C The following block handles the case of a successful return from the

 C core integrator (KFLAG = 0).  Test for stop conditions.

 C-----------------------------------------------------------------------

  300  init = 1

       GO TO (310, 400, 330, 340, 350), itask

 C ITASK = 1.  If TOUT has been reached, interpolate. -------------------

  310  IF ((tn - tout)*h .LT. 0.0e0) GO TO 250

       CALL sintdy (tout, 0, rwork(lyh), nyh, y, iflag)

       t = tout

       GO TO 420

 C ITASK = 3.  Jump to exit if TOUT was reached. ------------------------

  330  IF ((tn - tout)*h .GE. 0.0e0) GO TO 400

       GO TO 250

 C ITASK = 4.  See if TOUT or TCRIT was reached.  Adjust H if necessary.

  340  IF ((tn - tout)*h .LT. 0.0e0) GO TO 345

       CALL sintdy (tout, 0, rwork(lyh), nyh, y, iflag)

       t = tout

       GO TO 420

  345  hmx = abs(tn) + abs(h)

       ihit = abs(tn - tcrit) .LE. 100.0e0*uround*hmx

       IF (ihit) GO TO 400

       tnext = tn + h*(1.0e0 + 4.0e0*uround)

       IF ((tnext - tcrit)*h .LE. 0.0e0) GO TO 250

       h = (tcrit - tn)*(1.0e0 - 4.0e0*uround)

       jstart = -2

       GO TO 250

 C ITASK = 5.  See if TCRIT was reached and jump to exit. ---------------

  350  hmx = abs(tn) + abs(h)

       ihit = abs(tn - tcrit) .LE. 100.0e0*uround*hmx

 C-----------------------------------------------------------------------

 C Block G.

 C The following block handles all successful returns from SLSODE.

 C If ITASK .NE. 1, Y is loaded from YH and T is set accordingly.

 C ISTATE is set to 2, and the optional outputs are loaded into the

 C work arrays before returning.

 C-----------------------------------------------------------------------

  400  DO 410 i = 1,n

  410    y(i) = rwork(i+lyh-1)

       t = tn

       IF (itask .NE. 4 .AND. itask .NE. 5) GO TO 420

       IF (ihit) t = tcrit

  420  istate = 2

       rwork(11) = hu

       rwork(12) = h

       rwork(13) = tn

       iwork(11) = nst

       iwork(12) = nfe

       iwork(13) = nje

       iwork(14) = nqu

       iwork(15) = nq

       RETURN

 C-----------------------------------------------------------------------

 C Block H.

 C The following block handles all unsuccessful returns other than

 C those for illegal input.  First the error message routine is called.

 C If there was an error test or convergence test failure, IMXER is set.

 C Then Y is loaded from YH and T is set to TN.  The optional outputs

 C are loaded into the work arrays before returning.

 C-----------------------------------------------------------------------

 C The maximum number of steps was taken before reaching TOUT. ----------

  500  msg = 'SLSODE-  At current T (=R1), MXSTEP (=I1) steps   '

       CALL xerrwv (msg, 50, 201, 0, 0, 0, 0, 0, 0.0e0, 0.0e0)

       msg = '      taken on this call before reaching TOUT     '

       CALL xerrwv (msg, 50, 201, 0, 1, mxstep, 0, 1, tn, 0.0e0)

       istate = -1

       GO TO 580

 C EWT(I) .LE. 0.0 for some I (not at start of problem). ----------------

  510  ewti = rwork(lewt+i-1)

       msg = .LE.'SLSODE-  At T (=R1), EWT(I1) has become R2  0.'

       CALL xerrwv (msg, 50, 202, 0, 1, i, 0, 2, tn, ewti)

       istate = -6

       GO TO 580

 C Too much accuracy requested for machine precision. -------------------

  520  msg = 'SLSODE-  At T (=R1), too much accuracy requested  '

       CALL xerrwv (msg, 50, 203, 0, 0, 0, 0, 0, 0.0e0, 0.0e0)

       msg = '      for precision of machine..  see TOLSF (=R2) '

       CALL xerrwv (msg, 50, 203, 0, 0, 0, 0, 2, tn, tolsf)

       rwork(14) = tolsf

       istate = -2

       GO TO 580

 C KFLAG = -1.  Error test failed repeatedly or with ABS(H) = HMIN. -----

  530  msg = 'SLSODE-  At T(=R1) and step size H(=R2), the error'

       CALL xerrwv (msg, 50, 204, 0, 0, 0, 0, 0, 0.0e0, 0.0e0)

       msg = '      test failed repeatedly or with ABS(H) = HMIN'

       CALL xerrwv (msg, 50, 204, 0, 0, 0, 0, 2, tn, h)

       istate = -4

       GO TO 560

 C KFLAG = -2.  Convergence failed repeatedly or with ABS(H) = HMIN. ----

  540  msg = 'SLSODE-  At T (=R1) and step size H (=R2), the    '

       CALL xerrwv (msg, 50, 205, 0, 0, 0, 0, 0, 0.0e0, 0.0e0)

       msg = '      corrector convergence failed repeatedly     '

       CALL xerrwv (msg, 50, 205, 0, 0, 0, 0, 0, 0.0e0, 0.0e0)

       msg = '      or with ABS(H) = HMIN   '

       CALL xerrwv (msg, 30, 205, 0, 0, 0, 0, 2, tn, h)

       istate = -5

 C Compute IMXER if relevant. -------------------------------------------

  560  big = 0.0e0

       imxer = 1

       DO 570 i = 1,n

         SIZE = abs(rwork(i+lacor-1)*rwork(i+lewt-1))

         IF (big .GE. size) GO TO 570

         big = SIZE

         imxer = i

  570    CONTINUE

       iwork(16) = imxer

 C Set Y vector, T, and optional outputs. -------------------------------

  580  DO 590 i = 1,n

  590    y(i) = rwork(i+lyh-1)

       t = tn

       rwork(11) = hu

       rwork(12) = h

       rwork(13) = tn

       iwork(11) = nst

       iwork(12) = nfe

       iwork(13) = nje

       iwork(14) = nqu

       iwork(15) = nq

       RETURN

 C-----------------------------------------------------------------------

 C Block I.

 C The following block handles all error returns due to illegal input

 C (ISTATE = -3), as detected before calling the core integrator.

 C First the error message routine is called.  If the illegal input

 C is a negative ISTATE, the run is aborted (apparent infinite loop).

 C-----------------------------------------------------------------------

  601  msg = 'SLSODE-  ISTATE (=I1) illegal '

       CALL xerrwv (msg, 30, 1, 0, 1, istate, 0, 0, 0.0e0, 0.0e0)

       IF (istate .LT. 0) GO TO 800

       GO TO 700

  602  msg = 'SLSODE-  ITASK (=I1) illegal  '

       CALL xerrwv (msg, 30, 2, 0, 1, itask, 0, 0, 0.0e0, 0.0e0)

       GO TO 700

  603  msg = .GT.'SLSODE-  ISTATE  1 but SLSODE not initialized '

       CALL xerrwv (msg, 50, 3, 0, 0, 0, 0, 0, 0.0e0, 0.0e0)

       GO TO 700

  604  msg = .LT.'SLSODE-  NEQ (=I1)  1     '

       CALL xerrwv (msg, 30, 4, 0, 1, neq(1), 0, 0, 0.0e0, 0.0e0)

       GO TO 700

  605  msg = 'SLSODE-  ISTATE = 3 and NEQ increased (I1 to I2)  '

       CALL xerrwv (msg, 50, 5, 0, 2, n, neq(1), 0, 0.0e0, 0.0e0)

       GO TO 700

  606  msg = 'SLSODE-  ITOL (=I1) illegal   '

       CALL xerrwv (msg, 30, 6, 0, 1, itol, 0, 0, 0.0e0, 0.0e0)

       GO TO 700

  607  msg = 'SLSODE-  IOPT (=I1) illegal   '

       CALL xerrwv (msg, 30, 7, 0, 1, iopt, 0, 0, 0.0e0, 0.0e0)

       GO TO 700

  608  msg = 'SLSODE-  MF (=I1) illegal     '

       CALL xerrwv (msg, 30, 8, 0, 1, mf, 0, 0, 0.0e0, 0.0e0)

       GO TO 700

  609  msg = .LT..GE.'SLSODE-  ML (=I1) illegal.. 0 or NEQ (=I2)'

       CALL xerrwv (msg, 50, 9, 0, 2, ml, neq(1), 0, 0.0e0, 0.0e0)

       GO TO 700

  610  msg = .LT..GE.'SLSODE-  MU (=I1) illegal.. 0 or NEQ (=I2)'

       CALL xerrwv (msg, 50, 10, 0, 2, mu, neq(1), 0, 0.0e0, 0.0e0)

       GO TO 700

  611  msg = .LT.'SLSODE-  MAXORD (=I1)  0  '

       CALL xerrwv (msg, 30, 11, 0, 1, maxord, 0, 0, 0.0e0, 0.0e0)

       GO TO 700

  612  msg = .LT.'SLSODE-  MXSTEP (=I1)  0  '

       CALL xerrwv (msg, 30, 12, 0, 1, mxstep, 0, 0, 0.0e0, 0.0e0)

       GO TO 700

  613  msg = .LT.'SLSODE-  MXHNIL (=I1)  0  '

       CALL xerrwv (msg, 30, 13, 0, 1, mxhnil, 0, 0, 0.0e0, 0.0e0)

       GO TO 700

  614  msg = 'SLSODE-  TOUT (=R1) behind T (=R2)      '

       CALL xerrwv (msg, 40, 14, 0, 0, 0, 0, 2, tout, t)

       msg = '      Integration direction is given by H0 (=R1)  '

       CALL xerrwv (msg, 50, 14, 0, 0, 0, 0, 1, h0, 0.0e0)

       GO TO 700

  615  msg = .LT.'SLSODE-  HMAX (=R1)  0.0  '

       CALL xerrwv (msg, 30, 15, 0, 0, 0, 0, 1, hmax, 0.0e0)

       GO TO 700

  616  msg = .LT.'SLSODE-  HMIN (=R1)  0.0  '

       CALL xerrwv (msg, 30, 16, 0, 0, 0, 0, 1, hmin, 0.0e0)

       GO TO 700

  617  CONTINUE

       msg='SLSODE-  RWORK length needed, LENRW (=I1), exceeds LRW (=I2)'

       CALL xerrwv (msg, 60, 17, 0, 2, lenrw, lrw, 0, 0.0e0, 0.0e0)

       GO TO 700

  618  CONTINUE

       msg='SLSODE-  IWORK length needed, LENIW (=I1), exceeds LIW (=I2)'

       CALL xerrwv (msg, 60, 18, 0, 2, leniw, liw, 0, 0.0e0, 0.0e0)

       GO TO 700

  619  msg = .LT.'SLSODE-  RTOL(I1) is R1  0.0        '

       CALL xerrwv (msg, 40, 19, 0, 1, i, 0, 1, rtoli, 0.0e0)

       GO TO 700

  620  msg = .LT.'SLSODE-  ATOL(I1) is R1  0.0        '

       CALL xerrwv (msg, 40, 20, 0, 1, i, 0, 1, atoli, 0.0e0)

       GO TO 700

  621  ewti = rwork(lewt+i-1)

       msg = .LE.'SLSODE-  EWT(I1) is R1  0.0         '

       CALL xerrwv (msg, 40, 21, 0, 1, i, 0, 1, ewti, 0.0e0)

       GO TO 700

  622  CONTINUE

       msg='SLSODE-  TOUT (=R1) too close to T(=R2) to start integration'

       CALL xerrwv (msg, 60, 22, 0, 0, 0, 0, 2, tout, t)

       GO TO 700

  623  CONTINUE

       msg='SLSODE-  ITASK = I1 and TOUT (=R1) behind TCUR - HU (= R2)  '

       CALL xerrwv (msg, 60, 23, 0, 1, itask, 0, 2, tout, tp)

       GO TO 700

  624  CONTINUE

       msg='SLSODE-  ITASK = 4 OR 5 and TCRIT (=R1) behind TCUR (=R2)   '

       CALL xerrwv (msg, 60, 24, 0, 0, 0, 0, 2, tcrit, tn)

       GO TO 700

  625  CONTINUE

       msg='SLSODE-  ITASK = 4 or 5 and TCRIT (=R1) behind TOUT (=R2)   '

       CALL xerrwv (msg, 60, 25, 0, 0, 0, 0, 2, tcrit, tout)

       GO TO 700

  626  msg = 'SLSODE-  At start of problem, too much accuracy   '

       CALL xerrwv (msg, 50, 26, 0, 0, 0, 0, 0, 0.0e0, 0.0e0)

       msg='      requested for precision of machine..  See TOLSF (=R1) '

       CALL xerrwv (msg, 60, 26, 0, 0, 0, 0, 1, tolsf, 0.0e0)

       rwork(14) = tolsf

       GO TO 700

  627  msg = 'SLSODE-  Trouble in SINTDY.  ITASK = I1, TOUT = R1'

       CALL xerrwv (msg, 50, 27, 0, 1, itask, 0, 1, tout, 0.0e0)

 C

  700  istate = -3

       RETURN

 C

  800  msg = 'SLSODE-  Run aborted.. apparent infinite loop     '

       CALL xerrwv (msg, 50, 303, 2, 0, 0, 0, 0, 0.0e0, 0.0e0)

       RETURN

 C----------------------- END OF SUBROUTINE SLSODE ----------------------

       END

max
charNDArray max(char d, const charNDArray &m)
Definition: chNDArray.cc:230

min
charNDArray min(char d, const charNDArray &m)
Definition: chNDArray.cc:207

sewset
subroutine sewset(N, ITOL, RTOL, ATOL, YCUR, EWT)
Definition: sewset.f:2

sintdy
subroutine sintdy(T, K, YH, NYH, DKY, IFLAG)
Definition: sintdy.f:2

slsode
subroutine slsode(F, NEQ, Y, T, TOUT, ITOL, RTOL, ATOL, ITASK, ISTATE, IOPT, RWORK, LRW, IWORK, LIW, JAC, MF)
Definition: slsode.f:3

sprepj
subroutine sprepj(NEQ, Y, YH, NYH, EWT, FTEM, SAVF, WM, IWM, F, JAC)
Definition: sprepj.f:3

ssolsy
subroutine ssolsy(WM, IWM, X, TEM)
Definition: ssolsy.f:2

sstode
subroutine sstode(NEQ, Y, YH, NYH, YH1, EWT, SAVF, ACOR, WM, IWM, F, JAC, PJAC, SLVS)
Definition: sstode.f:3

xerrwv
subroutine xerrwv(MSG, NMES, NERR, LEVEL, NI, I1, I2, NR, R1, R2)
Definition: xerrwv.f:3