cbinu.f

Go to the documentation of this file.

      SUBROUTINE cbinu(Z, FNU, KODE, N, CY, NZ, RL, FNUL, TOL, ELIM,
     * ALIM)
C***BEGIN PROLOGUE  CBINU
C***REFER TO  CBESH,CBESI,CBESJ,CBESK,CAIRY,CBIRY
C
C     CBINU COMPUTES THE I FUNCTION IN THE RIGHT HALF Z PLANE
C
C***ROUTINES CALLED  CASYI,CBUNI,CMLRI,CSERI,CUOIK,CWRSK
C***END PROLOGUE  CBINU
      COMPLEX CW, CY, CZERO, Z
      REAL ALIM, AZ, DFNU, ELIM, FNU, FNUL, RL, TOL
      INTEGER I, INW, KODE, N, NLAST, NN, NUI, NW, NZ
      dimension cy(n), cw(2)
      DATA czero / (0.0e0,0.0e0) /
C
      nz = 0
      az = cabs(z)
      nn = n
      dfnu = fnu + float(n-1)
      IF (az.LE.2.0e0) GO TO 10
      IF (az*az*0.25e0.GT.dfnu+1.0e0) GO TO 20
   10 CONTINUE
C-----------------------------------------------------------------------
C     POWER SERIES
C-----------------------------------------------------------------------
      CALL cseri(z, fnu, kode, nn, cy, nw, tol, elim, alim)
      inw = iabs(nw)
      nz = nz + inw
      nn = nn - inw
      IF (nn.EQ.0) RETURN
      IF (nw.GE.0) GO TO 120
      dfnu = fnu + float(nn-1)
   20 CONTINUE
      IF (az.LT.rl) GO TO 40
      IF (dfnu.LE.1.0e0) GO TO 30
      IF (az+az.LT.dfnu*dfnu) GO TO 50
C-----------------------------------------------------------------------
C     ASYMPTOTIC EXPANSION FOR LARGE Z
C-----------------------------------------------------------------------
   30 CONTINUE
      CALL casyi(z, fnu, kode, nn, cy, nw, rl, tol, elim, alim)
      IF (nw.LT.0) GO TO 130
      GO TO 120
   40 CONTINUE
      IF (dfnu.LE.1.0e0) GO TO 70
   50 CONTINUE
C-----------------------------------------------------------------------
C     OVERFLOW AND UNDERFLOW TEST ON I SEQUENCE FOR MILLER ALGORITHM
C-----------------------------------------------------------------------
      CALL cuoik(z, fnu, kode, 1, nn, cy, nw, tol, elim, alim)
      IF (nw.LT.0) GO TO 130
      nz = nz + nw
      nn = nn - nw
      IF (nn.EQ.0) RETURN
      dfnu = fnu+float(nn-1)
      IF (dfnu.GT.fnul) GO TO 110
      IF (az.GT.fnul) GO TO 110
   60 CONTINUE
      IF (az.GT.rl) GO TO 80
   70 CONTINUE
C-----------------------------------------------------------------------
C     MILLER ALGORITHM NORMALIZED BY THE SERIES
C-----------------------------------------------------------------------
      CALL cmlri(z, fnu, kode, nn, cy, nw, tol)
      IF(nw.LT.0) GO TO 130
      GO TO 120
   80 CONTINUE
C-----------------------------------------------------------------------
C     MILLER ALGORITHM NORMALIZED BY THE WRONSKIAN
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
C     OVERFLOW TEST ON K FUNCTIONS USED IN WRONSKIAN
C-----------------------------------------------------------------------
      CALL cuoik(z, fnu, kode, 2, 2, cw, nw, tol, elim, alim)
      IF (nw.GE.0) GO TO 100
      nz = nn
      DO 90 i=1,nn
        cy(i) = czero
   90 CONTINUE
      RETURN
  100 CONTINUE
      IF (nw.GT.0) GO TO 130
      CALL cwrsk(z, fnu, kode, nn, cy, nw, cw, tol, elim, alim)
      IF (nw.LT.0) GO TO 130
      GO TO 120
  110 CONTINUE
C-----------------------------------------------------------------------
C     INCREMENT FNU+NN-1 UP TO FNUL, COMPUTE AND RECUR BACKWARD
C-----------------------------------------------------------------------
      nui = int(fnul-dfnu) + 1
      nui = max0(nui,0)
      CALL cbuni(z, fnu, kode, nn, cy, nw, nui, nlast, fnul, tol, elim,
     * alim)
      IF (nw.LT.0) GO TO 130
      nz = nz + nw
      IF (nlast.EQ.0) GO TO 120
      nn = nlast
      GO TO 60
  120 CONTINUE
      RETURN
  130 CONTINUE
      nz = -1
      IF(nw.EQ.(-2)) nz=-2
      RETURN
      END