cacai.f

Go to the documentation of this file.

      SUBROUTINE cacai(Z, FNU, KODE, MR, N, Y, NZ, RL, TOL, ELIM, ALIM)
C***BEGIN PROLOGUE  CACAI
C***REFER TO  CAIRY
C
C     CACAI APPLIES THE ANALYTIC CONTINUATION FORMULA
C
C         K(FNU,ZN*EXP(MP))=K(FNU,ZN)*EXP(-MP*FNU) - MP*I(FNU,ZN)
C                 MP=PI*MR*CMPLX(0.0,1.0)
C
C     TO CONTINUE THE K FUNCTION FROM THE RIGHT HALF TO THE LEFT
C     HALF Z PLANE FOR USE WITH CAIRY WHERE FNU=1/3 OR 2/3 AND N=1.
C     CACAI IS THE SAME AS CACON WITH THE PARTS FOR LARGER ORDERS AND
C     RECURRENCE REMOVED. A RECURSIVE CALL TO CACON CAN RESULT IF CACON
C     IS CALLED FROM CAIRY.
C
C***ROUTINES CALLED  CASYI,CBKNU,CMLRI,CSERI,CS1S2,R1MACH
C***END PROLOGUE  CACAI
      COMPLEX csgn, cspn, c1, c2, y, z, zn, cy
      REAL alim, arg, ascle, az, cpn, dfnu, elim, fmr, fnu, pi, rl,
     * sgn, spn, tol, yy, r1mach
      INTEGER inu, iuf, kode, mr, n, nn, nw, nz
      dimension y(n), cy(2)
      DATA pi / 3.14159265358979324e0 /
      nz = 0
      zn = -z
      az = cabs(z)
      nn = n
      dfnu = fnu + float(n-1)
      IF (az.LE.2.0e0) go to 10
      IF (az*az*0.25e0.GT.dfnu+1.0e0) go to 20
   10 CONTINUE
C-----------------------------------------------------------------------
C     POWER SERIES FOR THE I FUNCTION
C-----------------------------------------------------------------------
      CALL cseri(zn, fnu, kode, nn, y, nw, tol, elim, alim)
      go to 40
   20 CONTINUE
      IF (az.LT.rl) go to 30
C-----------------------------------------------------------------------
C     ASYMPTOTIC EXPANSION FOR LARGE Z FOR THE I FUNCTION
C-----------------------------------------------------------------------
      CALL casyi(zn, fnu, kode, nn, y, nw, rl, tol, elim, alim)
      IF (nw.LT.0) go to 70
      go to 40
   30 CONTINUE
C-----------------------------------------------------------------------
C     MILLER ALGORITHM NORMALIZED BY THE SERIES FOR THE I FUNCTION
C-----------------------------------------------------------------------
      CALL cmlri(zn, fnu, kode, nn, y, nw, tol)
      IF(nw.LT.0) go to 70
   40 CONTINUE
C-----------------------------------------------------------------------
C     ANALYTIC CONTINUATION TO THE LEFT HALF PLANE FOR THE K FUNCTION
C-----------------------------------------------------------------------
      CALL cbknu(zn, fnu, kode, 1, cy, nw, tol, elim, alim)
      IF (nw.NE.0) go to 70
      fmr = float(mr)
      sgn = -sign(pi,fmr)
      csgn = cmplx(0.0e0,sgn)
      IF (kode.EQ.1) go to 50
      yy = -aimag(zn)
      cpn = cos(yy)
      spn = sin(yy)
      csgn = csgn*cmplx(cpn,spn)
   50 CONTINUE
C-----------------------------------------------------------------------
C     CALCULATE CSPN=EXP(FNU*PI*I) TO MINIMIZE LOSSES OF SIGNIFICANCE
C     WHEN FNU IS LARGE
C-----------------------------------------------------------------------
      inu = int(fnu)
      arg = (fnu-float(inu))*sgn
      cpn = cos(arg)
      spn = sin(arg)
      cspn = cmplx(cpn,spn)
      IF (mod(inu,2).EQ.1) cspn = -cspn
      c1 = cy(1)
      c2 = y(1)
      IF (kode.EQ.1) go to 60
      iuf = 0
      ascle = 1.0e+3*r1mach(1)/tol
      CALL cs1s2(zn, c1, c2, nw, ascle, alim, iuf)
      nz = nz + nw
   60 CONTINUE
      y(1) = cspn*c1 + csgn*c2
      RETURN
   70 CONTINUE
      nz = -1
      IF(nw.EQ.(-2)) nz=-2
      RETURN
      END