r9lgmc.f

Go to the documentation of this file.

*DECK R9LGMC
      FUNCTION r9lgmc (X)
C***BEGIN PROLOGUE  R9LGMC
C***SUBSIDIARY
C***PURPOSE  Compute the log Gamma correction factor so that
C            LOG(GAMMA(X)) = LOG(SQRT(2*PI)) + (X-.5)*LOG(X) - X
C            + R9LGMC(X).
C***LIBRARY   SLATEC (FNLIB)
C***CATEGORY  C7E
C***TYPE      SINGLE PRECISION (R9LGMC-S, D9LGMC-D, C9LGMC-C)
C***KEYWORDS  COMPLETE GAMMA FUNCTION, CORRECTION TERM, FNLIB,
C             LOG GAMMA, LOGARITHM, SPECIAL FUNCTIONS
C***AUTHOR  Fullerton, W., (LANL)
C***DESCRIPTION
C
C Compute the log gamma correction factor for X .GE. 10.0 so that
C  LOG (GAMMA(X)) = LOG(SQRT(2*PI)) + (X-.5)*LOG(X) - X + R9LGMC(X)
C
C Series for ALGM       on the interval  0.          to  1.00000D-02
C                                        with weighted error   3.40E-16
C                                         log weighted error  15.47
C                               significant figures required  14.39
C                                    decimal places required  15.86
C
C***REFERENCES  (NONE)
C***ROUTINES CALLED  CSEVL, INITS, R1MACH, XERMSG
C***REVISION HISTORY  (YYMMDD)
C   770801  DATE WRITTEN
C   890531  Changed all specific intrinsics to generic.  (WRB)
C   890531  REVISION DATE from Version 3.2
C   891214  Prologue converted to Version 4.0 format.  (BAB)
C   900315  CALLs to XERROR changed to CALLs to XERMSG.  (THJ)
C   900720  Routine changed from user-callable to subsidiary.  (WRB)
C***END PROLOGUE  R9LGMC
      dimension algmcs(6)
      LOGICAL first
      SAVE algmcs, nalgm, xbig, xmax, first
      DATA algmcs( 1) /    .1666389480 45186e0 /
      DATA algmcs( 2) /   -.0000138494 817606e0 /
      DATA algmcs( 3) /    .0000000098 108256e0 /
      DATA algmcs( 4) /   -.0000000000 180912e0 /
      DATA algmcs( 5) /    .0000000000 000622e0 /
      DATA algmcs( 6) /   -.0000000000 000003e0 /
      DATA first /.true./
C***FIRST EXECUTABLE STATEMENT  R9LGMC
      IF (first) THEN
         nalgm = inits(algmcs, 6, r1mach(3))
         xbig = 1.0/sqrt(r1mach(3))
         xmax = exp(min(log(r1mach(2)/12.0), -log(12.0*r1mach(1))) )
      ENDIF
      first = .false.
C
      IF (x .LT. 10.0) CALL xermsg('SLATEC', 'R9LGMC',
     +   'X MUST BE GE 10', 1, 2)
      IF (x.GE.xmax) go to 20
C
      r9lgmc = 1.0/(12.0*x)
      IF (x.LT.xbig) r9lgmc = csevl(2.0*(10./x)**2-1., algmcs, nalgm)/x
      RETURN
C
 20   r9lgmc = 0.0
      CALL xermsg('SLATEC', 'R9LGMC', 'X SO BIG R9LGMC UNDERFLOWS', 2,
     +   1)
      RETURN
C
      END