d9lgic.f

Go to the documentation of this file.

*DECK D9LGIC
      DOUBLE PRECISION FUNCTION d9lgic (A, X, ALX)
C***BEGIN PROLOGUE  D9LGIC
C***SUBSIDIARY
C***PURPOSE  Compute the log complementary incomplete Gamma function
C            for large X and for A .LE. X.
C***LIBRARY   SLATEC (FNLIB)
C***CATEGORY  C7E
C***TYPE      DOUBLE PRECISION (R9LGIC-S, D9LGIC-D)
C***KEYWORDS  COMPLEMENTARY INCOMPLETE GAMMA FUNCTION, FNLIB, LARGE X,
C             LOGARITHM, SPECIAL FUNCTIONS
C***AUTHOR  Fullerton, W., (LANL)
C***DESCRIPTION
C
C Compute the log complementary incomplete gamma function for large X
C and for A .LE. X.
C
C***REFERENCES  (NONE)
C***ROUTINES CALLED  D1MACH, XERMSG
C***REVISION HISTORY  (YYMMDD)
C   770701  DATE WRITTEN
C   890531  Changed all specific intrinsics to generic.  (WRB)
C   890531  REVISION DATE from Version 3.2
C   891214  Prologue converted to Version 4.0 format.  (BAB)
C   900315  CALLs to XERROR changed to CALLs to XERMSG.  (THJ)
C   900720  Routine changed from user-callable to subsidiary.  (WRB)
C***END PROLOGUE  D9LGIC
      DOUBLE PRECISION a, x, alx, eps, fk, p, r, s, t, xma, xpa, d1mach
      SAVE eps
      DATA eps / 0.d0 /
C***FIRST EXECUTABLE STATEMENT  D9LGIC
      IF (eps.EQ.0.d0) eps = 0.5d0*d1mach(3)
C
      xpa = x + 1.0d0 - a
      xma = x - 1.d0 - a
C
      r = 0.d0
      p = 1.d0
      s = p
      DO 10 k=1,300
        fk = k
        t = fk*(a-fk)*(1.d0+r)
        r = -t/((xma+2.d0*fk)*(xpa+2.d0*fk)+t)
        p = r*p
        s = s + p
        IF (abs(p).LT.eps*s) go to 20
 10   CONTINUE
      CALL xermsg('SLATEC', 'D9LGIC',
     +   'NO CONVERGENCE IN 300 TERMS OF CONTINUED FRACTION', 1, 2)
C
 20   d9lgic = a*alx - x + log(s/xpa)
C
      RETURN
      END