dnedk.f

Go to the documentation of this file.

C Work performed under the auspices of the U.S. Department of Energy
C by Lawrence Livermore National Laboratory under contract number 
C W-7405-Eng-48.
C
      SUBROUTINE dnedk(X,Y,YPRIME,NEQ,RES,JACK,PSOL,
     *   h,wt,jstart,idid,rpar,ipar,phi,gamma,savr,delta,e,
     *   wm,iwm,cj,cjold,cjlast,s,uround,epli,sqrtn,rsqrtn,
     *   epcon,jcalc,jflg,kp1,nonneg,ntype,iernls)
C
C***BEGIN PROLOGUE  DNEDK
C***REFER TO  DDASPK
C***DATE WRITTEN   891219   (YYMMDD)
C***REVISION DATE  900926   (YYMMDD)
C***REVISION DATE  940701   (YYMMDD)
C
C
C-----------------------------------------------------------------------
C***DESCRIPTION
C
C     DNEDK solves a nonlinear system of
C     algebraic equations of the form
C     G(X,Y,YPRIME) = 0 for the unknown Y.
C
C     The method used is a matrix-free Newton scheme.
C
C     The parameters represent
C     X         -- Independent variable.
C     Y         -- Solution vector at x.
C     YPRIME    -- Derivative of solution vector
C                  after successful step.
C     NEQ       -- Number of equations to be integrated.
C     RES       -- External user-supplied subroutine
C                  to evaluate the residual.  See RES description
C                  in DDASPK prologue.
C     JACK     --  External user-supplied routine to update
C                  the preconditioner.  (This is optional).
C                  See JAC description for the case
C                  INFO(12) = 1 in the DDASPK prologue.
C     PSOL      -- External user-supplied routine to solve
C                  a linear system using preconditioning. 
C                  (This is optional).  See explanation inside DDASPK.
C     H         -- Appropriate step size for this step.
C     WT        -- Vector of weights for error criterion.
C     JSTART    -- Indicates first call to this routine.
C                  If JSTART = 0, then this is the first call,
C                  otherwise it is not.
C     IDID      -- Completion flag, output by DNEDK.
C                  See IDID description in DDASPK prologue.
C     RPAR,IPAR -- Real and integer arrays used for communication
C                  between the calling program and external user
C                  routines.  They are not altered within DASPK.
C     PHI       -- Array of divided differences used by
C                  DNEDK.  The length is NEQ*(K+1), where
C                  K is the maximum order.
C     GAMMA     -- Array used to predict Y and YPRIME.  The length
C                  is K+1, where K is the maximum order.
C     SAVR      -- Work vector for DNEDK of length NEQ.
C     DELTA     -- Work vector for DNEDK of length NEQ.
C     E         -- Error accumulation vector for DNEDK of length NEQ.
C     WM,IWM    -- Real and integer arrays storing
C                  matrix information for linear system
C                  solvers, and various other information.
C     CJ        -- Parameter always proportional to 1/H.
C     CJOLD     -- Saves the value of CJ as of the last call to DITMD.
C                  Accounts for changes in CJ needed to
C                  decide whether to call DITMD.
C     CJLAST    -- Previous value of CJ.
C     S         -- A scalar determined by the approximate rate
C                  of convergence of the Newton iteration and used
C                  in the convergence test for the Newton iteration.
C
C                  If RATE is defined to be an estimate of the
C                  rate of convergence of the Newton iteration,
C                  then S = RATE/(1.D0-RATE).
C
C                  The closer RATE is to 0., the faster the Newton
C                  iteration is converging; the closer RATE is to 1.,
C                  the slower the Newton iteration is converging.
C
C                  On the first Newton iteration with an up-dated
C                  preconditioner S = 100.D0, Thus the initial
C                  RATE of convergence is approximately 1.
C
C                  S is preserved from call to call so that the rate
C                  estimate from a previous step can be applied to
C                  the current step.
C     UROUND    -- Unit roundoff.
C     EPLI      -- convergence test constant.
C                  See DDASPK prologue for more details.
C     SQRTN     -- Square root of NEQ.
C     RSQRTN    -- reciprical of square root of NEQ.
C     EPCON     -- Tolerance to test for convergence of the Newton
C                  iteration.
C     JCALC     -- Flag used to determine when to update
C                  the Jacobian matrix.  In general:
C
C                  JCALC = -1 ==> Call the DITMD routine to update
C                                 the Jacobian matrix.
C                  JCALC =  0 ==> Jacobian matrix is up-to-date.
C                  JCALC =  1 ==> Jacobian matrix is out-dated,
C                                 but DITMD will not be called unless
C                                 JCALC is set to -1.
C     JFLG      -- Flag showing whether a Jacobian routine is supplied.
C     KP1       -- The current order + 1;  updated across calls.
C     NONNEG    -- Flag to determine nonnegativity constraints.
C     NTYPE     -- Identification code for the DNEDK routine.
C                   1 ==> modified Newton; iterative linear solver.
C                   2 ==> modified Newton; user-supplied linear solver.
C     IERNLS    -- Error flag for nonlinear solver.
C                   0 ==> nonlinear solver converged.
C                   1 ==> recoverable error inside non-linear solver.
C                  -1 ==> unrecoverable error inside non-linear solver.
C
C     The following group of variables are passed as arguments to
C     the Newton iteration solver.  They are explained in greater detail
C     in DNSK:
C        TOLNEW, MULDEL, MAXIT, IERNEW
C
C     IERTYP -- Flag which tells whether this subroutine is correct.
C               0 ==> correct subroutine.
C               1 ==> incorrect subroutine.
C
C-----------------------------------------------------------------------
C***ROUTINES CALLED
C   RES, JACK, DDWNRM, DNSK
C
C***END PROLOGUE  DNEDK
C
C
      IMPLICIT DOUBLE PRECISION(a-h,o-z)
      dimension y(*),yprime(*),wt(*)
      dimension phi(neq,*),savr(*),delta(*),e(*)
      dimension wm(*),iwm(*)
      dimension gamma(*),rpar(*),ipar(*)
      EXTERNAL  res, jack, psol
C
      parameter(lnre=12, lnje=13, llocwp=29, llciwp=30)
C
      SAVE muldel, maxit, xrate
      DATA muldel/0/, maxit/4/, xrate/0.25d0/
C
C     Verify that this is the correct subroutine.
C
      iertyp = 0
      IF (ntype .NE. 1) THEN
         iertyp = 1
         go to 380
         ENDIF
C
C     If this is the first step, perform initializations.
C
      IF (jstart .EQ. 0) THEN
         cjold = cj
         jcalc = -1
         s = 100.d0
         ENDIF
C
C     Perform all other initializations.
C
      iernls = 0
      lwp = iwm(llocwp)
      liwp = iwm(llciwp)
C
C     Decide whether to update the preconditioner.
C
      IF (jflg .NE. 0) THEN
         temp1 = (1.0d0 - xrate)/(1.0d0 + xrate)
         temp2 = 1.0d0/temp1
         IF (cj/cjold .LT. temp1 .OR. cj/cjold .GT. temp2) jcalc = -1
         IF (cj .NE. cjlast) s = 100.d0
      ELSE
         jcalc = 0
         ENDIF
C
C     Looping point for updating preconditioner with current stepsize.
C
300   CONTINUE
C
C     Initialize all error flags to zero.
C
      ierpj = 0
      ires = 0
      iersl = 0
      iernew = 0
C
C     Predict the solution and derivative and compute the tolerance
C     for the Newton iteration.
C
      DO 310 i=1,neq
         y(i)=phi(i,1)
310      yprime(i)=0.0d0
      DO 330 j=2,kp1
         DO 320 i=1,neq
            y(i)=y(i)+phi(i,j)
320         yprime(i)=yprime(i)+gamma(j)*phi(i,j)
330   CONTINUE
      eplin = epli*epcon
      tolnew = eplin
C
C     Call RES to initialize DELTA.
C
      iwm(lnre)=iwm(lnre)+1
      CALL res(x,y,yprime,cj,delta,ires,rpar,ipar)
      IF (ires .LT. 0) go to 380
C
C
C     If indicated, update the preconditioner.
C     Set JCALC to 0 as an indicator that this has been done.
C
      IF(jcalc .EQ. -1)THEN
         iwm(lnje) = iwm(lnje) + 1
         jcalc=0
         CALL jack(res, ires, neq, x, y, yprime, wt, delta, e, h, cj,
     *      wm(lwp), iwm(liwp), ierpj, rpar, ipar)
         cjold=cj
         s = 100.d0
         IF (ires .LT. 0)  go to 380
         IF (ierpj .NE. 0) go to 380
      ENDIF
C
C     Call the nonlinear Newton solver.
C
      CALL dnsk(x,y,yprime,neq,res,psol,wt,rpar,ipar,savr,
     *   delta,e,wm,iwm,cj,sqrtn,rsqrtn,eplin,epcon,
     *   s,temp1,tolnew,muldel,maxit,ires,iersl,iernew)
C
      IF (iernew .GT. 0 .AND. jcalc .NE. 0) THEN
C
C     The Newton iteration had a recoverable failure with an old
C     preconditioner.  Retry the step with a new preconditioner.
C
         jcalc = -1
         go to 300
      ENDIF
C
      IF (iernew .NE. 0) go to 380
C
C     The Newton iteration has converged.  If nonnegativity of
C     solution is required, set the solution nonnegative, if the
C     perturbation to do it is small enough.  If the change is too
C     large, then consider the corrector iteration to have failed.
C
      IF(nonneg .EQ. 0) go to 390
      DO 360 i = 1,neq
 360    delta(i) = min(y(i),0.0d0)
      delnrm = ddwnrm(neq,delta,wt,rpar,ipar)
      IF(delnrm .GT. epcon) go to 380
      DO 370 i = 1,neq
 370    e(i) = e(i) - delta(i)
      go to 390
C
C
C     Exits from nonlinear solver.
C     No convergence with current preconditioner.
C     Compute IERNLS and IDID accordingly.
C
380   CONTINUE
      IF (ires .LE. -2 .OR. iersl .LT. 0 .OR. iertyp .NE. 0) THEN
         iernls = -1
         IF (ires .LE. -2) idid = -11
         IF (iersl .LT. 0) idid = -13
         IF (iertyp .NE. 0) idid = -15
      ELSE
         iernls =  1
         IF (ires .EQ. -1) idid = -10
         IF (ierpj .NE. 0) idid = -5
         IF (iersl .GT. 0) idid = -14
      ENDIF
C
C
390   jcalc = 1
      RETURN
C
C------END OF SUBROUTINE DNEDK------------------------------------------
      END